Listbox.List hata veriyor.

[esnaf88]

Private Sub UserForm_Initialize()
ListeyiYenile
End Sub

Sub ListeyiYenile()
Dim wsFirma As Worksheet
Dim SonSatir As Long

Set wsFirma = ThisWorkbook.Sheets("Firmalar")
lstFirmalar.Clear

SonSatir = wsFirma.Cells(Rows.Count, 1).End(xlUp).Row
If SonSatir > 1 Then
lstFirmalar.List = wsFirma.Range("A2:A" & SonSatir).Value
End If
End Sub

Arkadaşlar merhaba.
Yukarıdaki Makroyu çalıştırdığımda eğer "Firmalar" sayfasında kayıtlı firma yoksa kayıt yapıyor, kaydı tamamlar tamamlamaz aşağıdaki resimde görülen hatayı veriyor.
Söz konusu hatayı nasıl çözebilirim?
Yardımcı olacak arkadaşlara teşekkür ederim.

 

[Muzaffer Ali]

Merhaba.
Listaboxun ayarlarında geçersiz bir şey yapmışsınız.
Form üzerindeki Listbox u silin yerine yenisini ekleyip deneyin.
Yeni Listboxun adını "lstFirmalar " yapmayı unutmayın.

Eğer olmazsa dosyanızı ekleyin kontrol edelim.

 

[esnaf88]

Merhaba.
Listaboxun ayarlarında geçersiz bir şey yapmışsınız.
Form üzerindeki Listbox u silin yerine yenisini ekleyip deneyin.
Yeni Listboxun adını "lstFirmalar " yapmayı unutmayın.

Eğer olmazsa dosyanızı ekleyin kontrol edelim.

Dosyayı ekledim.

 

[Muzaffer Ali]

Sadece bir firma olduğunda lstFirmalar.List ile listboxa veri alınamıyor. Çünkü = dizi değişkeni olmalı.
Tek bir firma olduğunda AddItem ile listeye eklenecek şekilde kodu güncelledim.

Sub ListeyiYenile()
    Dim wsFirma As Worksheet
    Dim SonSatir As Long
    
    Set wsFirma = ThisWorkbook.Sheets("Firmalar")
    lstFirmalar.Clear
    
    SonSatir = wsFirma.Cells(Rows.Count, 1).End(xlUp).Row
    If SonSatir > 2 Then
        lstFirmalar.List = wsFirma.Range("A2:A" & SonSatir).Value
    ElseIf SonSatir > 1 Then
        lstFirmalar.AddItem wsFirma.Range("A2").Value
    End If
End Sub

 

[esnaf88]

Teşekkür ederim. İyi çalışmalar dilerim.

 

[esnaf88]

Sadece bir firma olduğunda lstFirmalar.List ile listboxa veri alınamıyor. Çünkü = dizi değişkeni olmalı.
Tek bir firma olduğunda AddItem ile listeye eklenecek şekilde kodu güncelledim.

Tekrar merhaba.
Userform1 içindeki listbox'ta sıralanan tarih bilgileri önce ay sonra gün olarak geliyor. Gün/Ay/Yıl olarak nasıl düzeltebilirim.
Teşekkür ederim.

 

[Ouzz_z]

' Tüm Verileri ListBox'a Getir
Sub VerileriListele()
    Dim SonSatir As Long
    Dim i As Long, x As Long
    
    lstStok.Clear
    SonSatir = ws.Cells(Rows.Count, 1).End(xlUp).Row
    
    If SonSatir < 2 Then Exit Sub
    
    Dim Veri As Variant
    
        Veri = ws.Range("A2:Q" & SonSatir).Value
        
        For i = 1 To UBound(Veri, 1)
            If IsDate(Veri(i, 2)) Then
                Veri(i, 2) = Format(Veri(i, 2), "dd.mm.yyyy")
            End If
        Next i
    
    lstStok.List = Veri
End Sub

 

[esnaf88]

Çok teşekkür ederim. İyi çalışmalar.