Access penceresini nasıl görünmez yapıyoruz?

[aherab]

Arkadaşlar uygulamayı açınca aşağıdaki gibi resim gibi oluyo sonra aç dediğinizde access ekranı kapanıyor resim 2 gibi sadece uygulama olsun böylece daha profesyonel bir uygulama elde etme şansımız var bunu nasıl yapabiliriz ?

 

[PLTNAZR]

ACCESS GÖRÜNÜMÜNDEN KURTARMA


yeni bir makro oluşturun eylem e kod çalıştır secin işlev kutusuna da fAccessWindow ("Hide", False, False) yazın
programın ilk açılan formun özeliklerinde açıldıgında yerine de makro adını yazın tüm from ve raporlarının açıl ve kalıcı özeliklerini de evet e ayarlayın yeni bir modül oluşturun içinede
Private Declare Function IsWindowVisible Lib "user32" (ByVal hwnd As Long) As Long
Dim dwReturn As Long

Const SW_HIDE = 0
Const SW_SHOWNORMAL = 1
Const SW_SHOWMINIMIZED = 2
Const SW_SHOWMAXIMIZED = 3

Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, _
ByVal nCmdShow As Long) As Long

Public Function fAccessWindow(Optional Procedure As String, Optional SwitchStatus As Boolean, Optional StatusCheck As Boolean) As Boolean
If Procedure = "Hide" Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
End If
If Procedure = "Show" Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
End If
If Procedure = "Minimize" Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMINIMIZED)
End If
If SwitchStatus = True Then
If IsWindowVisible(hWndAccessApp) = 1 Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
Else
dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
End If
End If
If StatusCheck = True Then
If IsWindowVisible(hWndAccessApp) = 0 Then
fAccessWindow = False
End If
If IsWindowVisible(hWndAccessApp) = 1 Then
fAccessWindow = True
End If
End If
End Function

Ayrıca Raporlarınızın özelliklerden "Açıldığında" olay yordamına aşağıdaki kodu yazın. Bunun sebebi rapor açılıyor ama minimize oluyor bunu engellemek için yazıyoruz.
Kod:
Private Sub Report_Open(Cancel As Integer)
DoCmd.Maximize
End Sub

 

[aherab]

çok teşekkürler cevabınız için

 

[PLTNAZR]

Rica Ederim Kolay gelsin...