Acces'te Rapor alanlarının çizelge halinte getirilmesi

[abkbek]

İyi geceler,

Hazırladığım bir veritabanındaki bir sorguda farklı veri tipleri (Metin, sayı, tarih ve not alanları gibi) ve boyutlarından oluşan 10 alan (Sütun) var. bunları raporda görüntülerken kenar çizgilerinden faydalanarak çizelge haline getiriyorum.

Ancak alanlardaki verilere göre satır yükseklikleri otomatik ayarlandığından satırlarda biri dar, diğeri geniş oluyor.

oysa ben satır içerisindeki en uzun metnin yüksekliğine göre tüm satırın otomatik ayarlanmasını istiyorum.

yani excel'deki satırlar için "en uygun yükseklik" ayarı ile ayarlandığı gibi görüntülemek istiyorum. alanların çizgilerini kaldırarak satırlar arasında sadece yatay çizgi koyduğumda bu defa sütun çizgileri yok oluyor.
Lütfen bu problemi çözmeme yardımcı olur musunuz?

 

[GKMER]

Public Sub MakeBoxesGrow(ThisReport As Report)
Dim X1 As Single
Dim X2 As Single
Dim Y1 As Single
Dim Y2 As Single
Dim Offset As Single
Dim Color As Long
Dim ThisControl As Control
Dim MaxHeight As Single

For Each ThisControl In ThisReport.Section(acDetail).Controls
If ThisControl.Visible = True Then
If ThisControl.Height > MaxHeight Then
MaxHeight = ThisControl.Height
End If
End If
Next ThisControl

ThisReport.ScaleMode = 1

Offset = 0
ThisReport.DrawWidth = 3
Color = RGB(0, 0, 0) '

For Each ThisControl In ThisReport.Section(acDetail).Controls
If ThisControl.Visible = True Then

X1 = ThisControl.Left - Offset
Y1 = ThisControl.Top - Offset

X2 = ThisControl.Left + ThisControl.Width + Offset
Y2 = ThisControl.Top + MaxHeight + Offset

ThisReport.Line (X1, Y1)-(X2, Y2), Color, B
End If
Next ThisControl

Set ThisControl = Nothing
End Sub


bunu bir modüle ekle


Private Sub Ayrıntı_Print(Cancel As Integer, PrintCount As Integer)
MakeBoxesGrow Me
End Sub

bunuda raporda düzenlersen sorunun çözülür

 

[abkbek]

Teşekkürler

Çok ama çok teşekkür ederim. ben bu problemi çözebilmek için o kadar uykusuz geceler geçirdim ki yaptığınız iyiliğe karşı duyduğum minnettarlığımı inanın kelimelerle ifade etmem mümkün değil. ama beni bir çocuk gibi sevindirdiğinizi ve başarmanın hazzını yaşamamı sağladığınızı ifade etmek isterim. tekrar tekrar çok teşekkür ederim.

 

[GKMER]

bende bunu bu forumdan almıştım. bu foruma emeği geçenlere çok çok teşekkür ederim. hayat paylaşınca güzel.

 

[abkbek]

gerçekten de insanların hiçbir menfaat beklentisi olmadan ihtiyacı olanlarla bilgilerini paylaşması ve yardımcı olması ne kadar büyük bir nezaket..