açılır pencereden 1 den fazla veri secebilme

[GOGO05]

örnek tablodaki sarı renge boyadığım açılır pencereden 1 den fazla veri nasıl secebilirim.

 

[Necdet]

Merhaba,

Makrolu Çözüm sundum size.

Sayfa1'in SelectionChange olayı aşağıdaki gibi değişti.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 
    If Intersect(Target, [c:d]) Is Nothing Or Target.Row < 2 Then Exit Sub
    If Target.Column = 3 Then
        Takvim.Show
    Else
        UserForm1.Show
    End If
    
End Sub

Eklediğim UserForm1'in Kodları ise aşağıdaki gibidir.

12 Adet CheckBox ekledim, gerekirse siz bunları çoğaltabilirsiniz.

Private Sub CommandButton1_Click()
    Dim i   As Integer, _
        Deg As String
    
    For i = 1 To 12
        If Controls("Checkbox" & i).Visible = True And Controls("CheckBox" & i) = True Then
            If Len(Deg) = 0 Then
                Deg = Controls("Checkbox" & i).Caption
            Else
                Deg = Deg & ", " & Controls("Checkbox" & i).Caption
            End If
        End If
    Next i
    
    ActiveCell.Value = Deg
    Unload Me
    
End Sub

Private Sub CommandButton2_Click()
    Unload Me
End Sub

Private Sub UserForm_Initialize()
    Dim i   As Integer
    Dim Sh2 As Worksheet
    
    Set Sh2 = Sheets("Sayfa2")
    
    For i = 2 To Sh2.Cells(Rows.Count, "B").End(3).Row
        Controls("Checkbox" & i - 1).Caption = Sh2.Cells(i, "B")
    Next i
    
    For i = i - 1 To 12
        Controls("Checkbox" & i).Visible = False
    Next i
    
End Sub

 

[GOGO05]

teşekürler elinize sağlık necdet bey...

 

[Necdet]

teşekürler elinize sağlık necdet bey...

Güle güle kullanınız.