Bir sayfadan diğer sayfaya sütunları kopyalama

[hakki83]

Değerli hocalarımız iyi günler

Örnek dosyadaki İlk sayfanın A sütununu,
İkinci sayfadaki A sütununa;

İlk sayfanın SONUÇLAR başlıklı son sütununu,
İkinci sayfadaki B sütununa kopyalayacak kodu rica ederim.

Son sütunun yeri sabit değildir, değişkendir.

Detaylı açıklamayı dosya içine de yazdım.

Teşekkürler.

 

[tukayf]

Ekstra talepler yoksa. Bunu makro kaydet ile çözebilirsiniz hocam. Bir deneyin isterseniz.

 

[hakki83]

Şu an bilgisayar başında değilim. Son sütunun yeri değişken, yani hep aynı yerde değil.
Eğer bu şekilde makro kaydet yöntemiyle doğru kod bulunacaksa, tabi denerim.

 

[dEdE]

Merhaba,
Aşağıdaki kodu dener misiniz?

Private Sub CommandButton1_Click()
    Set ws1 = Sheets("VERİ SAYFASI")
    ss = ws1.Cells(Rows.Count, "A").End(xlUp).Row
    sk = ws1.Cells(1, Columns.Count).End(xlToLeft).Column
    
    ws1.Columns("A:A").Copy Sheets("RAPOR SAYFASI").Columns("A:A")
    ws1.Range(ws1.Cells(1, sk), ws1.Cells(ss, sk)).Copy Sheets("RAPOR SAYFASI").Range("B1")
End Sub

 

[Korhan Ayhan]

Alternatif;

Option Explicit

Private Sub CommandButton1_Click()
    Dim S1 As Worksheet, S2 As Worksheet, Bul As Range, Son As Long
    
    Set S1 = Sheets("RAPOR SAYFASI")
    Set S2 = Sheets("VERİ SAYFASI")
    
    Son = S2.Cells(S2.Rows.Count, 1).End(3).Row
    
    With S1
        .Range("A:B").Clear
        .Range("A1:A" & Son).Value = S2.Range("A1:A" & Son).Value
        Set Bul = S2.Rows(1).Find("SONUÇLAR", LookAt:=xlWhole)
        If Not Bul Is Nothing Then
            .Range("B1:B" & Son).Value = Bul.Resize(Son).Value
        End If
    End With
    
    Set Bul = Nothing
    Set S1 = Nothing
    Set S2 = Nothing

    MsgBox "Veri aktarımı tamamlanmıştır.", vbInformation
End Sub

 

[hakki83]

Dede hocam ve Korhan hocalarımızın kodları tam doğrudur. Emeklerinize sağlık.