Birleştirilmiş hücrelerin temizlenmesi

[mars2]

İyi Akşamlar;

Excel çalışma kitabımın etiket sayfasının C42 ile C52 hücrelerini temizleme istiyorum. Aşağıdaki makroları deneme rağmen silmiyor. Neden ve hata nereden kaynaklanmaktadır.

C42 ile D42 hücresi birleşmiş ve C42 olarak gözüküyor.
C43 ile D43 hücresi birleşmiş ve C42 olarak gözüküyor.

Private Sub Worksheet_Change(ByVal Target As Range)

S1 = Sheets("etiket (2)")
S1.Range("C42:C52"). ClearContents
S1.Range("H42:H52") .ClearContents

End sub

.Clearcontents yerine =Empty metodun uyguladım yine çalışmadı

 

[mars2]

İyi Akşamlar;

Excel çalışma kitabımın etiket sayfasının C42 ile C52 hücrelerini temizleme istiyorum. Aşağıdaki makroları deneme rağmen silmiyor. Neden ve hata nereden kaynaklanmaktadır.

C42 ile D42 hücresi birleşmiş ve C42 olarak gözüküyor.
C43 ile D43 hücresi birleşmiş ve C42 olarak gözüküyor.

Private Sub Worksheet_Change(ByVal Target As Range)

S1 = Sheets("etiket (2)")
S1.Range("C42:C52"). ClearContents
S1.Range("H42:H52") .ClearContents

End sub

.Clearcontents yerine =Empty metodun uyguladım yine çalışmadı

 

[Ouzz_z]

Sayfa ataması yaparken Set kullanınız. Ayrıca her değişiklikte çalıştırdığınız için kısır döngüye girip hata verecektir. Çünkü son aralık silindiğinde bu da bir değişiklik olacak ve excel donacak. Düzeltmeyi inceleyiniz.

Private Sub Worksheet_Change(ByVal Target As Range)
    Application.EnableEvents = False
    
        Set S1 = Sheets("etiket (2)")
        S1.Range("C42:C52").ClearContents
        S1.Range("H42:H52").ClearContents
        
    Application.EnableEvents = True
End Sub

 

[muhasebeciyiz]

Kodun iki temel sorunu var:

1. Nesneyi Set ile atamıyorsun → S1 = Sheets("etiket (2)") yanlış.
2. Worksheet_Change içinde hücre silmek olayı yeniden tetikler → Application.EnableEvents kapatılmadığı için olay kendi kendini çağırır (sonsuz döngü/hataya yol açar).
   Ayrıca noktanın önündeki boşluk (. ClearContents) VBA’da sözdizimi hatasıdır. Bir de birleştirilmiş hücrelerde yalnızca sol-üst hücre değer tutar; temizleme bu hücreye uygulanmazsa bir şey olmaz.

Aşağıdaki kodu ilgili sayfanın (etiket (2)) kod modülüne değil, genel bir modüle koyup manuel çalıştırabilirsin ya da sayfa modülünde Worksheet_Change kullanacaksan olayları kapatıp açmalısın.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Me.Range("C9")) Is Nothing Then Exit Sub
    If Target.CountLarge > 1 Then Exit Sub   

    On Error GoTo ExitHandler
    Application.EnableEvents = False

    Dim rng As Range
    Set rng = Me.Range("C42:D52,H42:I52")

    ' Seçenek A: Her şeyi temizle (Muzaffer Ali hocamızın yaptığı gibi)
    rng.ClearContents

    ' Seçenek B: (İSTERSENİZ) sadece sabit değerleri temizle
    ' Böylece formüller korunur, formül sonuçları yeni C9'a göre kendiliğinden güncellenir.
    'On Error Resume Next
    'rng.SpecialCells(xlCellTypeConstants).ClearContents
    'On Error GoTo ExitHandler

ExitHandler:
    Application.EnableEvents = True
End Sub

Sayfa Modülüne ekleyiniz

 

[muhasebeciyiz]

Birleştirilmiş hücrelerin temizlenmesi

İyi Akşamlar; Excel çalışma kitabımın etiket sayfasının C42 ile C52 hücrelerini temizleme istiyorum. Aşağıdaki makroları deneme rağmen silmiyor. Neden ve hata nereden kaynaklanmaktadır. C42 ile D42 hücresi birleşmiş ve C42 olarak gözüküyor. C43 ile D43 hücresi birleşmiş ve C42 olarak...

www.excel.web.tr

Konu açılmış lütfen tekrar açmayınız

 

[mars2]

İyi Günler;

Konu hakkında ilgi ve yardımlarınıza teşekkürler.

Konu, yanlışlıkla ikinci kez açılmıştır.

C9 hücresinde dosya nosunu yazınca C42, C43, C44, C45, C46, C47, C48, C49,C50, C51, C52 hücrelerine dosya ile isimler gelmektedir.

C42 ile D42 hücresi ile birleşmesi sonucu C42 olarak gözükmektedir. Diğer hücrelerde aynı şekildedir.

Ancak, dosyalarda farklı ism veya isimler bulunmaktadır. Örneğin C42, C43, C44 vd farklı isim bulunduğu, C9'a yeni no girdiğimde C42 ile C52 arsında bulunan isimlerin silinmesini istemekteyim.

Yukarıda vermiş olduğunuz kodlarını Worksheet_Change eventi ile uygulamama rağmen fazla isimler silinmemeketdir,

Teşekkür

 

[Muzaffer Ali]

Merhaba.

Aşağıdaki kodu deneyiniz.

Birleştirilmiş hücreler birlikte adres belirtilmelidir.
Range("C42").ClearContents
Hata verir
Range("C42:D42").ClearContents
Şeklinde olmalı.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Range("C9"), Target) Is Nothing Then
        Application.EnableEvents = False
        With ThisWorkbook.Worksheets("etiket (2)")
            .Range("C42:D52").ClearContents
            .Range("H42:I52").ClearContents
        End With
        Application.EnableEvents = True
    End If
End Sub

Yada aşağıdaki gibi olmalıdır.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Range("C9"), Target) Is Nothing Then
        Application.EnableEvents = False
        With ThisWorkbook.Worksheets("etiket (2)")
            .Range("C42:C52, H42:H52").Value = ""
        End With
        Application.EnableEvents = True
    End If
End Sub

 

[Korhan Ayhan]

Mükerrer konu başlıkları tarafımca birleştirilmiştir...

 

[muhasebeciyiz]

Muzaffer Hocamızın paylaştığı çözüm çok güzel olup birleşik hücreleri kapsayacak şekilde C-D ve H-I sütunlarını birlikte temizlemektedir.

Benim ilk örneğim sadece C ve H sütunlarını temizlediği için (özellikle birleştirme C-D ve H-I üzerinde ise) etkisi eksik kalmış olabilir.
Bende 4 nolu mesajımı alternatif olarak ekledim.İsterseniz kullanabilirsiniz.

 

[mars2]

Sayın Muzaffer Ali;

İlgi ve kod için teşekkürler.
Kod istediğim gibi çalışmaktadır