Bulma Fonksiyonu

[yildizzx]

Merhaba,

Bul-Değiştir formu yapmak istiyorum ve verilerimi gizli bir sayfada tutuyorum ancak ilgili sayfayı seçtiğimde bu sayfa gizli olduğu için bulunamadı hatası veriyor.
Bu hatayı nasıl aşabilirim. Yardımlarınızı rica ederim.

Private Sub CommandButtonARA_Click()
On Error GoTo bitir
aranan = InputBox("ID Numarasını Giriniz", "ARA")
Worksheets("Veri").Select
Range("A:A").Find(aranan).Select

sil_satir = ActiveCell.Row

TextBox5.Value = Worksheets("Veri").Cells(sil_satir, 1)
TextBox1.Value = Worksheets("Veri").Cells(sil_satir, 2)
TextBox2.Value = Worksheets("Veri").Cells(sil_satir, 3)
TextBox3.Value = Worksheets("Veri").Cells(sil_satir, 4)
ComboBox1.Value = Worksheets("Veri").Cells(sil_satir, 6)
TextBox4.Value = Worksheets("Veri").Cells(sil_satir, 7)
Exit Sub
bitir: MsgBox "Aranan ID Bulunamadı", , "HATA"
End Sub

 

[AdemCan]

Gizli sayfayı görünür yapıp, işlem sonunda tekrar gizleyerek yapılabilir.

Private Sub CommandButtonARA_Click()
Application.ScreenUpdating = False
Worksheets("Veri").Visible = True

On Error GoTo bitir
aranan = InputBox("ID Numarasını Giriniz", "ARA")
Worksheets("Veri").Select
Range("A:A").Find(aranan).Select

sil_satir = ActiveCell.Row

TextBox5.Value = Worksheets("Veri").Cells(sil_satir, 1)
TextBox1.Value = Worksheets("Veri").Cells(sil_satir, 2)
TextBox2.Value = Worksheets("Veri").Cells(sil_satir, 3)
TextBox3.Value = Worksheets("Veri").Cells(sil_satir, 4)
ComboBox1.Value = Worksheets("Veri").Cells(sil_satir, 6)
TextBox4.Value = Worksheets("Veri").Cells(sil_satir, 7)
Exit Sub
bitir: MsgBox "Aranan ID Bulunamadı", , "HATA"

Worksheets("Veri").Visible = False
Application.ScreenUpdating = True
End Sub

 

[Muzaffer Ali]

Merhaba.

Sayfayı seçmek zorunda değilsiniz sayfa referansını belirtmeniz yeterli.
Aşağıdaki kodu deneyiniz.

Private Sub CommandButtonARA_Click()
    Dim Aranan As String
    Dim Bul As Range
    Aranan = InputBox("ID Numarasını Giriniz", "ARA")
    With Worksheets("Veri")
        Set Bul = .Range("A:A").Find(Aranan)
        If Bul Is Nothing Then
            MsgBox "Aradığınız bulunamıyor."
            Exit Sub
        Else
            TextBox5.Value = .Cells(Bul.Row, 1)
            TextBox1.Value = .Cells(Bul.Row, 2)
            TextBox2.Value = .Cells(Bul.Row, 3)
            TextBox3.Value = .Cells(Bul.Row, 4)
            ComboBox1.Value = .Cells(Bul.Row, 6)
            TextBox4.Value = .Cells(Bul.Row, 7)
        End If
    End With
End Sub

 

[Necdet]

Merhaba,

Arama yapacağınız sayfaya gitmeniz gerekmiyor.
Kodu Aşağıdaki gibi kullanınız.

Private Sub CommandButtonARA_Click()

    Dim c As Range
    Dim Aranan As String
    
    Aranan = InputBox("ID Numarasını Giriniz", "ARA")
    
    Set c = Sheets("Veri").Range("A:A").Find(Aranan, LookIn:=xlValues, LookAt:=xlWhole)
    If Not c Is Nothing Then
        TextBox5.Value = Worksheets("Veri").Cells(c.Row, 1)
    Else
        Range("F2") = "bulunamadı.."
    End If
    
    TextBox5.Value = Worksheets("Veri").Cells(c.Row, 1)
    TextBox1.Value = Worksheets("Veri").Cells(c.Row, 2)
    TextBox2.Value = Worksheets("Veri").Cells(c.Row, 3)
    TextBox3.Value = Worksheets("Veri").Cells(c.Row, 4)
    ComboBox1.Value = Worksheets("Veri").Cells(c.Row, 6)
    TextBox4.Value = Worksheets("Veri").Cells(c.Row, 7)
    Exit Sub
    
End Sub

 

[Necdet]

Geç kalmışım