Soru Combobox verilerine göre aktar

[sirkülasyon]

Kalem sayfasının
AA sütununda 2. satırdan itibaren Yıl yazılı (2021, 2022 gibi)
AB sütununda 2. satırdan itibaren Ay yazılı (Ocak, Haziran gibi)

Userform' da Combobox1 Yıl, Combobox2 Ay
USerform' da Yıl ve Ay seçildiği zaman Kalem sayfasında ki seçilen yıl ve seçilen aya ait satırlar (A : AD aralığı)
Silgi Sayfasına 2. satırdan itibaren alt alta aktarılması için yardımcı olabilir misiniz?

 

[ÖmerFaruk]

Sub Aktar()
    Dim Dizi As Variant, Liste1(), Liste2(), i As Integer, Son As Integer, Say1 As Integer, Say2 As Integer
    
    Dizi = Worksheets("Kalem").Range("A2").Resize(Worksheets("Kalem").Range("A" & Rows.Count).End(3).Row - 1, 30).Value
    ReDim Liste1(1 To UBound(Dizi), 1 To 30)
    ReDim Liste2(1 To UBound(Dizi), 1 To 30)
    For i = 1 To UBound(Dizi)
        If Dizi(i, 27) = CInt(Me.ComboBox1) And Dizi(i, 28) = Me.ComboBox2.Value Then
            Say1 = Say1 + 1
            For k = 1 To 30
                Liste1(Say1, k) = Dizi(i, k)
            Next k
        Else
            Say2 = Say2 + 1
            For k = 1 To 30
                Liste2(Say2, k) = Dizi(i, k)
            Next k
        End If
    Next i
    If Say1 > 0 Then
    Son = Worksheets("Silgi").Range("A" & Rows.Count).End(3).Row + 1
    Worksheets("Silgi").Range("A" & Son).Resize(Say1, 30) = Liste1
    Worksheets("Kalem").Range("A2:AD" & Rows.Count).ClearContents
    Worksheets("Kalem").Range("A2").Resize(Say2, 30) = Liste2
    End If
End Sub

 

[sirkülasyon]

Sayın ÖmerFaruk
Ellerinize sağlık. Sağ olasın

 

[ÖmerFaruk]

Sizler de sağolun.