Countıf Fonksiyonunda Mükerrer Kayıtı Bir Kere Say

[SER973]

Günaydın
Excel.Web.Tr Ailesi,

ConuntIf Fonsiyonu ile Değerleri Saydıra biliyoruz. Ancak Burada Mükerrer olanlar var ise Bir defa Saymasını nasıl sağlayabiliriz..

Örnek Dosyam Ektedir...

 

[Ömer]

Merhaba,

Mükerrerden kastınız nedir anlayamadım, miktar sütununda farklı olanların karşısındaki Kocaeli'lermi sayılacak. Soruyu biraz daha açarmısınız..

.

 

[SER973]

Merhaba
espiyonajl

Kocaeli Yanındaki Miktarları Sayacak Yanlız Aynı olan Miktarları Bir sefer Sayacak..

İlginize Teşekkürler...

 

[Ömer]

Merhaba
espiyonajl

Kocaeli Yanındaki Miktarları Sayacak Yanlız Aynı olan Miktarları Bir sefer Sayacak..

İlginize Teşekkürler...

=BAĞ_DEĞ_SAY(1/SIKLIK(EĞER($B$4:$B$30=D2;EĞER($A$4:$A$30<>"";KAÇINCI($A$4:$A$30;$A$4:$A$30;0)));SATIR(İNDİS($A$4:$A$30;0;0))-SATIR($A$4)+1))

Dizi formülüdür. ctrl shift enter tuş kombinasyonu ile giriniz..

.

 

[SER973]

Teşekkürler
espiyonajl

Elinize Sağlık... Öğretiniz için ayrıca teşeküürler...

 

[Merhum İdris SERDAR]

Günaydın
Excel.Web.Tr Ailesi,

ConuntIf Fonsiyonu ile Değerleri Saydıra biliyoruz. Ancak Burada Mükerrer olanlar var ise Bir defa Saymasını nasıl sağlayabiliriz..

Örnek Dosyam Ektedir...

.
E4 hücresine:

=SUMPRODUCT(--($B$4:$B$13=D2);--(1/COUNTIF($A$4:$A$13;$A$4:$A$13)))

yazıp, aşağıya kopyalayın.

.

 

[Ömer]

Rica ederim, iyi çalışmalar..

 

[SER973]

Sn. Yurttaş

Sizin Vermiş olduğunu Formül Çalışıyor. =SUMPRODUCT(--($B$4:$B$13=D2);--(1/COUNTIF($A$4:$A$13;$A$4:$A$13)))

Ancak Tabloya Veri ilave edileceğinden Hücre aralığını Genişlettiğimde
=SUMPRODUCT(--($B$4:$B$100=D2);--(1/COUNTIF($A$4:$A$100;$A$4:$A$100)))
"#DIV/0!" Hata Mesajı veriyor. Boş Hücreleri Sayamıyor Anladığın Kadarı ile.. Bu Sorunu nasıl aşarız..

 

[Merhum İdris SERDAR]

Sn. Yurttaş

Sizin Vermiş olduğunu Formül Çalışıyor. =SUMPRODUCT(--($B$4:$B$13=D2);--(1/COUNTIF($A$4:$A$13;$A$4:$A$13)))

Ancak Tabloya Veri ilave edileceğinden Hücre aralığını Genişlettiğimde
=SUMPRODUCT(--($B$4:$B$100=D2);--(1/COUNTIF($A$4:$A$100;$A$4:$A$100)))
"#DIV/0!" Hata Mesajı veriyor. Boş Hücreleri Sayamıyor Anladığın Kadarı ile.. Bu Sorunu nasıl aşarız..

Aşağıda yazdığım tüm formüller dizi formülleridir. CTRL FHIFT tuşlsarı basılı iken ENTER tuşu ile girmelisiniz.

Herhangi birisini kullanabilirsiniz.

=SUMPRODUCT(--($B$4:$B$13=D2);--(IF($A$4:$A$13="";0;1/COUNTIF($A$4:$A$13;$A$4:$A$13))))


=SUMPRODUCT(--($B$4:$B$13=D2);--(IF(LEN($A$4:$A$13);1/COUNTIF($A$4:$A$13;$A$4:$A$13))))


=SUMPRODUCT(COUNTIF($A$4:$A$13;$A$4:$A$13)/IF(NOT(COUNTIF($A$4:$A$13;$A$4:$A$13));1;COUNTIF($A$4:$A$13;$A$4:$A$13))^2;--($B$4:$B$13=D2))



.

 

[Ali]

Alternatif 1

=TOPLA.ÇARPIM(((A4:A100<>"")*(B4:B100=D2))/EĞERSAY(A4:A100;A4:A100&""))

Alternatif 2

Bu ikinci formül dizi formülüdür.

=TOPLA(EĞER(SIKLIK(EĞER(B4:B100=D2;KAÇINCI("~"&A4:A100;A4:A100&"";0));SATIR(A4:A100)-SATIR(A4)+1);1))