depo listesinden sonuca giden formüllerle ilgili

[modoste]

merhaba sayın hocalarım 2010 yılında firmam için depo tablosu hazırladım
forumdan sayın hocalarımdan daha önce öğrendiğim formülleri kullanarak kopyalayarak bi takım sonuçlar elde ettim

ekli çizelgemde malzeme adı kısmını benzersiz kayıtlarla listeliyorum
ve belirli tarihler arasında malzemelerin (adet-kutu-litre vs)birimlerine göre
giriş listesinden veri miktarlarını formülle R3 hücresinden başlayarak buldurabiliyorum.

R3 ten başlayan formülasyona hocalarım bakınca anlayacaklardır zaten
ben formülasyonda bir detayı yapamadım
mesela E sütununda asfalt plent depo ve konkasör depo diye 2 kısma ayırdım ve bu ifadeleri P38 arasına manuel yazdım
ESAYIYSA formülüyle hangisinden sonuç istiyosam diğerini silip R3 hücresindeki formülden sonuca gidiyorum.
P38 arasında hangi verileri yazıyosam sonuçları döksün ama veri yazmıyosam yani P38 arası boş ise formülün alacağı kriter tüm depoyu yani E sütunundaki herşey gibi döksün bu detayı yapamadım.

eğer bu kısmın formülünü anlayabilirsem AB3:AB19 arasındaki başka bi kriteri de yapabilicem

ayrıca çizelgede gizli kısımlar var ordada depo çıkışlar kısmı olucak ordaki formülleride ben sizden gelen yanıtlarla kendim dönüştürmeye çalışıcam

 

[Ömer]

Merhaba,

Detaylı deneme yapmadım,

R3:

=TOPLA.ÇARPIM(($A$3:$A$2000>=$R$1)*($A$3:$A$2000<=$S$1)*(EĞERSAY($P$3:$P$8;
$E$3:$E$2000)>((BAĞ_DEĞ_DOLU_SAY($P$3:$P$8)=0)*-1))*(EĞERSAY(
$AB$3:$AB$19;$B$3:$B$2000)>((BAĞ_DEĞ_DOLU_SAY($AB$3:$AB$19)=0)*-1))*
($D$3:$D$2000=$Q3)*($F$3:$F$2000=R$2)*($G$3:$G$2000))

.

 

[modoste]

*(EĞERSAY($P$3:$P$8;
$E$3:$E$2000)>((BAĞ_DEĞ_DOLU_SAY($P$3:$P$8)=0)*-1))
sayın hocam formülasyonu uyguladım sonuçlar tamam
formülasyonu anlamak adına yukarda yazdığım kısmın içeriğini anlayamadım formülü *1 deyip-1 yapmak nasıl bi sonuç çıkartıyo bunu açıklayabilirmisiniz.

 

[Ömer]

Kısaca açıklamaya çalışayım..

*(EĞERSAY($P$3:$P$8;$E$3:$E$2000)>((BAĞ_DEĞ_DOLU_SAY($P$3:$P$8)=0)*-1))


Formülde;

*(EĞERSAY($P$3:$P$8;$E$3:$E$2000)>((BAĞ_DEĞ_DOLU_SAY($P$3:$P$8)=0)*-1))

işaretli kısımda eğersayın >0 yada >-1 olma durumunu sağlanmıştır. 0 olduğunda >0 olduğu için eğersayda sıfır olanları dikkate almaz. Yani var olan değerleri hesaba katar. -1 olduğunda ise >-1 olacağından eğersayın ürettiği 0 değerlerinide dikkate alır. Bu durumda da tüm verileri işleme almış oluruz.

((BAĞ_DEĞ_DOLU_SAY($P$3:$P$8)=0)*-1))

bu kısmı eğerle;

EĞER(BAĞ_DEĞ_DOLU_SAY($P$3:$P$8)=0;-1;0) yazmakla aynı ifadedir.

Nedeni;

((BAĞ_DEĞ_DOLU_SAY($P$3:$P$8)=0)*-1))

işaretli kısım =0 durumuna göre DOĞRU yada YANLIŞ değeri üretir. Excelin mantıksal işleyişinde DOĞRU 1 YANLIŞ ise 0 değerini üretir. Buradan üretilen 1 yada 0 değerini -1 ile çarparsak 0 yada -1 değerini üretiriz. Bizim istediğimizde bu iki değerden birine ulaşmaktır. Eğer kullanmadan bu şekilde de yazılabilir.

.

 

[modoste]

sayın hocam eğersay kıyasından neden -1 değerini bulduruyoruz bu -1 i anlayamadım

 

[modoste]

formüle bir daha baktım hocam eğer aralıkta veri yoksa yani bağıl değer cevabı 0 ise -1 den büyük şartını almışız birde bağıl değer say 0 dan büyükse yi saymışız

anladım hocam mantığını formülün teşekkürler
sayın hocam bu formülün kenarında çıkanlar(gizli yerler) orayıda ben sizin mantıkla formüle etmeye çalışcam bocaladığımda yine size sorucam