ETOPLA Formülünü kısaltmak

[SeSi]

Merhaba,


Yaptığım bir tabloda aşağıdaki formülü kullanıyorum. Amacım; C6:C38 hücrelerinde "AHMET-AYSEL-CAFER" isimleri varsa, G6:G38 hücresindeki bu isimlerin karşısında bulunan rakamları toplatmak. İstediğim sonuç çıkıyor. Fakat bu formülü kısaltabilir miyim? Formül şöyle;

=ETOPLA($C$6:$C$38;"AHMET";$G$6:$G$38)+ETOPLA($C$6:$C$38;"AYSEL";$G$6:$G$38)+ETOPLA($C$6:$C$38;"CAFER";$G$6:$G$38)

Saygı ve teşekkürlerimi sunarım.

 

[Hüseyin]

Merhaba,
forumda çok sık görmediğim bir foksiyonu kullanarak bir örnek sunuyorum.

Ã?rnekte
DSUM (VSEÇTOPLA) foksiyonunu kullandım
Bu gurup fonksiyonlar bir listeden birden çok kriter bazında işlem yapmak için idealdir.

Ekteki örnekte:

A1:C29 -> arası veritabanımız
G1:G4 -> kriter alanı
K1 -> sonuç

şeklindedir.
Fonksiyonun kullanımı ise:
DSUM (veritabanı;toplanacak sütun numarası;kriter alanı)
yani
DSUM(A1:C29;3;G1:G4)

Bu önerten yola çıkarak kendi örneğinize adapte edebilirsiniz.
Umarım faydalı olur.

 

[SeSi]

Merhaba,

Dosyanızı inceledim. Alternatif bir formül olarak çok güzel.
Formülünüze göre, ayrı bir kriter alanı yaratmak gerekiyor. Ben ise ayrı kriter alanı yaratmadan yapmak istiyorum.
Yani istediğim sonucu veren fakat uzun olan formülümü kısaltmak istiyorum.

Saygı ve teşekkürlerimi sunarım.

 

[eksoy]

Merhaba Sayın Hüseyin ,
3 kişinin toplamı değilde isim isim toplamları bu fonksiyonla nasıl bulabilirim.

 

[Hüseyin]

Merhaba Sayın Hüseyin ,
3 kişinin toplamı değilde isim isim toplamları bu fonksiyonla nasıl bulabilirim.

Sayın eksoy,
bunun için Pivot Table özelliğini önerebilirim.
Forumda arama yaparsanız bu konuda bir çok örnek bulabilirsiniz.

 

[Hüseyin]

Sayın SeSi,
yine benim örnek olarak eklediğim dosyayı baz alarak aşağıdaki formülü istediğiniz hücreye yazın.
Eski G1:G4 ve K1 hücrelerindeki verileri silebilirsiniz.

=SUMPRODUCT(--(ISNUMBER(MATCH(A2:A29;{"Aysel";"Ahmet";"Cafer"};0)));C2:C29)

Bu yöntemi www.mrexcel.com sitesinde görmüştüm ve siz sorunca arayıp oradan aldım, güzel bir yaklaşım.
Bu örnek daha fazla isimle toplatma yapmak istediğinizde daha da faydalı.

 

[SeSi]

Sayın Hüseyin bey,

Size zahmet verdim. Formülü türkçeleştirdim.

=TOPLA.ÇARPIM(--(SAYIDIR(KAÇINCI(A2:A29;{"Aysel";"Ahmet";"Cafer"};0)));C2:C29)

ama #AD? hatası verdi.

Neyi yanlış yapmış olabilirim?

Saygı ve Teşekkürlerimi sunarım.

 

[Levent Menteşoğlu]

SAYIDIR yazımı hatalı yerine ESAYIYSA yı kullanın.

 

[SeSi]

Çok teşekkürler.

 

[uslu45]

merhaba;

benim de benzer bir sorunum var ancak ben isim veremiyorum çünkü çok fazla
örn: a sütunundaki isimlere karşılık gelen sayıları toplatmak istiyorum ama a sütununda bir isim birden fazla yazılmış
yani her isime gelen sayıları isim bazında toplamak

 

[zafer]

Merhaba

A sürünunda isimler B sütununda sayılar olduğunu varsayıyoruz

mesala C1 formülü yazın "AA" A sütünundaki isim
TOPLA.ÇARPIM((A1:A100="AA")*(B1:B100))

 

[uslu45]

teşekkür ederim
yardımcı oldun