EXCEL VERİ NUMARALANDIRMA

[gumrukdisticaret]

MERHABA

EXCELDE SAYFA BİR SEKMESİNDE ANA VERİLERİM VAR

• A Sütunu: 1 - 20 arası
• B Sütunu: 21 - 40 arası
• C Sütunu: 41 - 60 arası
• D Sütunu: 61 - 80 arası
• E Sütunu: 81 - 100 arası

BU VERİLERİMİN BAŞINA
1-20
21-40...
ŞEKLİNDE NUMARALANDIRMA YAPMAK İSTİYORUM. AŞAĞIDA YER ALAN
SAYFA 2 YE YAZDIĞIM FORMUL İLE BİRER SÜTUN BOŞLUK BIRAKIP DEVAM EDİYOR
FORMUL İLE SAYFA BİRDEN SAYFA 2 DEKİ BOŞLUKLARA NASIL ÇEKEBİLİRİM. TEK TEK UĞRAŞMAK İMKANSIZ. VERİLER ÇOK OLDUĞU İÇİN OLMUYOR. YARDIMCI OLURMUSUNUZ.

• A Sütunu: 1 - 20 arası
• C Sütunu: 21 - 40 arası
• E Sütunu: 41 - 60 arası
• G Sütunu: 61 - 80 arası
• I Sütunu: 81 - 100 arası (101. satıra gelindiğinde tekrar A sütunu 1'den başlayacak)

FORMÜL =EĞER(MOD(SÜTUN();2)=0;"";MOD(TAMSAYI((SÜTUN()-1)/2)*20+SATIR()-1;100)+1)

 

[Korhan Ayhan]

Merhaba,

Sayfa2 A1 hücresine aşağıdaki formülü uygulayınız. J1 hücresine kadar sürükleyiniz. Sonra alt hücrelere ihtiyacınız kadar sürükleyiniz.

=EĞER(MOD(SÜTUN();2)=1;MOD(TAMSAYI((SÜTUN()-1)/2)*20+MOD(SATIR()-1;20);100)+1;EĞERHATA(EĞER(KAYDIR(Sayfa1!$A$1;SATIR()-1;TAMSAYI((SÜTUN()-2)/2))=0;"";KAYDIR(Sayfa1!$A$1;SATIR()-1;TAMSAYI((SÜTUN()-2)/2)));""))

 

[gumrukdisticaret]

Teşekkürler hocam

 

[52779]

Alternatif çözüm olarak,

Excel 2021 kullanıcısı olduğunuzdan,
TEK hücreye yazılacak formülle Komple dökülmeli olarak ve de Genelleştirilmiş bir dizi elde etmek için aşağıdaki gibi formüle edilebilir.

Formülü, dizinin komple dökülebileceği bir alanda herhangi bir hücreye yazabilirsiniz. Sonuçlar komple dökülecektir.

Formül

=LET(k;20;str;500;stn;5;bos;1;a;DEVRİK_DÖNÜŞÜM(SIRALI(stn;k));b;SIRALI(;bos*(stn-1)+stn);EĞER(MOD(b;bos+1)=1;İNDİS(a;MOD(SIRALI(str;;0);k)+1;BÖLÜM(b-1;bos+1)+1);""))

Formül sizin sorunuza göre yazıldı. Ama genelleştirilebilir. Şöyle ki,
Formülde, LET işlevinden hemen sonra gelen parametrelere istediğiniz değerleri yazabilirsiniz.
Parametre k : 20 olarak yazılmış olup, kolonlara 20 şer 20 şer sıralı şekilde yazılmasını belirten parametredir. Bu değeri 30 yaparsanız dizi kolonlara 30 ar 30 ar yazılır.
Parametre str : Kaç satır veri yazdırmak istiyorsanız, o değer yazılacak. Formülde 500 satır olarak yazıldı. Değiştirilebilir..
Parametre stn : Sizde 5 kolon için veri yazılması istendiğinden bu parametre 5 olarak yazıldı. Ancak değiştirip başka değer yazılarak genelleştirilebilir.
Parametre bos : İki veri kolonu arasında BOŞ bırakılacak kolon adedini belirtir. Sizse 1 kolon veri ve bir kolon boş şeklinde 5 kolonluk veri dizisi olduğundan iki veri kolonu arasında, BOŞ bırakılacak kolon adedi 1 olduğundan 1 değeri yazıldı. arttırılıp azaltılabilir.

Not :
1 - Bu k, str, stn ve bos parametreleri 0 dan büyük tamsayı olmalıdır.
2 - Sizin sayfa1 deki veriler dediğiniz de zaten a parametresiyle tanımlanan DEVRİK_DÖNÜŞÜM(SIRALI(stn;k)) formülü ile elde edilen verilerdir. Bu dizide, Boş kolon yoktur.