İstenİlen HÜcreye Resİm YerleŞtİrme

[frksfu]

Dğerli arkadaşlar excele yeni başlayanlar forumunda açtığım bu konuya yanıt alamadım. Yardımcı olurmusunuz. Sn Ustalar resim konusundaki tüm sitedeki konuları aradım ancak benim istediğimi bulamadım. Benim istediğim bir hücreye ara komutu ile bir isim aratıyorum bu hücre içine isim gelincede yanındaki hücreye resim gelsin. İstediğimi anlatan dosyam ekte şimdiden çok teşekkür ederim.

 

[hamitcan]

Exceltip sitesinden bir örnek buldum. Herhalde işinizi görür.
Link: http://exceltip.com/st/Insert_pictures_using_VBA_in_Microsoft_Excel/486.html

'With the macro below you can insert pictures and fit them to any range in a worksheet.
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$C$4" Then Exit Sub
 TestInsertPictureInRange
End Sub

Sub TestInsertPictureInRange()
ActiveSheet.Pictures.Delete
InsertPictureInRange "C:\Resimlerim\" & [e4] & ".jpg", [g4]
End Sub

Sub InsertPictureInRange(PictureFileName As String, TargetCells As Range)
' inserts a picture and resizes it to fit the TargetCells range
Dim p As Object, t As Double, l As Double, w As Double, h As Double
    If TypeName(ActiveSheet) <> "Worksheet" Then Exit Sub
    If Dir(PictureFileName) = "" Then Exit Sub
    ' import picture
    Set p = ActiveSheet.Pictures.Insert(PictureFileName)
    ' determine positions
    With TargetCells
        t = .Top
        l = .Left
        w = .Offset(0, .Columns.Count).Left - .Left
        h = .Offset(.Rows.Count, 0).Top - .Top
    End With
    ' position picture
    With p
        .Top = t
        .Left = l
        .Width = w
        .Height = h
    End With
    Set p = Nothing
End Sub

 

[frksfu]

Sayın Hamitcan kardeşim Excele yeni başlayanlar bölümünde bu konuyu açtım epey bi cevap gelmemişti umudumu kesip bu bölümede yeni konu olarak açtım ancak bu gün Sayın ferhat Pazarçevirdi hocamız istediğim yanıtı verdi onun koduda sizinki ile hemen hemen aynı sizede ayrıca çok teşekkür ederim. sağolun varolun