Karışık bir işlem(örnek öss)

[bestercan]

Karışık bir işlem. şöyle izah edeyim:
öğrencilerin Öss sonuçlarını liste yapmak istiyorum. 1 öğrenciye ait sınav sonucunu web sayfasından aldım ve sayfa1 e yapıştırdım. Sayfa2 de ise bu sonuçların düzenlenmiş hali var. buraya kadar herşey normal.

bundan sonrası için ikinci bir öğrencinin sınav sonucunu webde sayfa 1deki bilgilerin üzerine kopyalama yapacağım. kopyalarsam sayfa 2deki bilgilerde değişecek. Sayfa 2 deki bilgilerindeğişmemesi için yada bir alt satıra yeni bilgileri dizmesi için nasıl bir formül uygulamalıyım.

umarım anlatabilmişimdir. Yardımcı olan herkese şimdiden teşekkür ederim

 

[Ferhat Pazarçevirdi]

Öncelikle, sizin formülle yaratmış olduğunuz "Sayfa2" kopyalanıp, "SABLON" adıyla yeni bir sayfa olarak projeye ilave edildi.

SABLON sayfası gizlendi.

Sayfa2'deki formüller silindi.

Sayfa1'e bir adet buton (CommandButton1) yerleştirildi.

Butona aşağıdaki kod yazıldı.

Private Sub CommandButton1_Click()
    Call Ogrenci_Bilgileri_Al
End Sub

Standart bir modül sayfası oluşturulup, aşağıdaki kodlar yazıldı.

Örnek dosyayı inceleyiniz.

Option Explicit
Sub Ogrenci_Bilgileri_Al()
    Dim TCK As String
    Dim rng As Range
    Dim bul As Range
    Dim str As Integer
 
    With Sheets("SABLON")
 
        If IsEmpty(.Cells(3, 1)) Then
            MsgBox "TC Kimlik No bilgisi okunamamıyor", vbCritical, "UYARI"
            Exit Sub
        End If
 
        TCK = .Cells(3, 1)
        Set rng = .Range("A3:AZ3")
 
    End With
 
    With Sheets("Sayfa2")
 
        Set bul = .Columns(1).Find(What:=TCK, _
                                   After:=.Range("A1"), _
                                   LookAt:=xlWhole, _
                                   SearchDirection:=xlNext)
        If Not bul Is Nothing Then
 
            Select Case MsgBox("Kimlik numaralı personel daha önce kaydedilmiş" & vbLf & _
                               "Varolan bilgilerin değiştirilmesini ister misiniz ?", vbYesNoCancel + vbQuestion, "UYARI")
                Case vbYes
                    .Range("A" & bul.Row & ":AZ" & bul.Row).Value = rng.Value
                Case vbNo
                    str = .Cells(65536, 1).End(xlUp).Row + 1
                    Application.Calculate
                    .Range("A" & str & ":AZ" & str).Value = rng.Value
                Case vbCancel
                    GoTo fpc
            End Select
 
        Else
            str = .Cells(65536, 1).End(xlUp).Row + 1
            Application.Calculate
           .Range("A" & str & ":AZ" & str).Value = rng.Value
        End If
 
    End With
 
fpc:
 
   Set rng = Nothing
    Set bul = Nothing
End Sub

 

[bestercan]

ferhat bey çok teşekkür ederim. işimi o kadar çok kolaylaştırdınız ki?:hihoho: :hihoho: :hihoho: