Şartlara bağlı olarak aynı tarihteki satırları saymak

[aercin]

Merhabalar... Belirli şartları sağlayan satırları tarihlerine göre sayarak ayrı bir sayfaya yazdırmak istiyorum... Dosya ektedir..

 

[Ömer]

Merhaba,

B2:

=TOPLA.ÇARPIM(((DEĞİŞTİR(Sayfa1!$B$2:$B$100;7;100;"")="212431")+
(DEĞİŞTİR(Sayfa1!$C$2:$C$100;7;100;"")="212431"))*(Sayfa1!$A$2:$A$100=B$1)*
(Sayfa1!$D$2:$D$100=$A2))

C2:

=TOPLA.ÇARPIM(((DEĞİŞTİR(Sayfa1!$B$2:$B$100;7;100;"")={"212228";"212238"})+
(DEĞİŞTİR(Sayfa1!$C$2:$C$100;7;100;"")={"212228";"212238"}))*
(Sayfa1!$A$2:$A$100=C$1)*(Sayfa1!$D$2:$D$100=$A2))

D2:

=TOPLA.ÇARPIM(((DEĞİŞTİR(Sayfa1!$B$2:$B$100;7;100;"")="212236")+
(DEĞİŞTİR(Sayfa1!$C$2:$C$100;7;100;"")="212236"))*(Sayfa1!$A$2:$A$100=D$1)*
(Sayfa1!$D$2:$D$100=$A2))

Hücrelerine yazarak alt satırlara kopyalayın.

Sıfır değerleri görmek istemezseniz. B2: Dson aralığını seçin hücre biçimlendirme isteğe uyarlanmıştan tür bölümüne,

[=0] "";Genel

yazın.

.

 

[Korhan Ayhan]

Selamlar,

Alternatif olarak aşağıdaki şekilde de kullanabilirsiniz.

B2 Hücresine;

=TOPLA.ÇARPIM((Sayfa1!$A$2:$A$1000=B$1)*((SOLDAN(Sayfa1!$B$2:$B$1000;6)="212431")+(SOLDAN(Sayfa1!$C$2:$C$1000;6)="212431"))*(Sayfa1!$D$2:$D$1000=$A2))

C2 Hücresine;

=TOPLA.ÇARPIM((Sayfa1!$A$2:$A$1000=C$1)*((SOLDAN(Sayfa1!$B$2:$B$1000;6)="212228")+(SOLDAN(Sayfa1!$B$2:$B$1000;6)="212238")+(SOLDAN(Sayfa1!$C$2:$C$1000;6)="212228")+(SOLDAN(Sayfa1!$B$2:$B$1000;6)="212238"))*(Sayfa1!$D$2:$D$1000=$A2))

D2 Hücresine;

=TOPLA.ÇARPIM((Sayfa1!$A$2:$A$1000=D$1)*((SOLDAN(Sayfa1!$B$2:$B$1000;6)="212236")+(SOLDAN(Sayfa1!$C$2:$C$1000;6)="212236"))*(Sayfa1!$D$2:$D$1000=$A2))

 

[aercin]

İkisi de çalıştı ve tam istediğim şey teşekkür ederim... Benim döküman bayağı uzun buraya sadece örnek verdim, uyguluyorum. Korhan Ayhan'ın yazdığı formülü anlayabildim.
Fakat Ömer beyin kullanmış olduğu DEĞİŞTİR formülünün kullanımıyla ilgili de küçük bir açıklama olabilirse çok daha güzel olacak benim için (Mesela formüldeki 7;100;"" ne ile ilgili)

 

[Korhan Ayhan]

Selamlar,

Ömer beyin önerdiği formülde kullanılan değiştir fonksiyonu B sütununda bulunan sayısal değerleri sizin sorgulamak istediğiniz değerlere eşitlemektedir. Sorgulamak istediğiniz değerlerler B sütunundaki verilerin ilk altı karakteridir.

Değiştir fonksiyonu ile B sütunundaki verilerin sadece ilk altı karakteri işleme alınarak sizin koşullarınızla eşleştirip sonuç elde edilmektedir.

Örnek;

2124312211 verisine değiştir formülünü uygularsak aşağıdaki sonucu elde edersiniz.

=DEĞİŞTİR(Sayfa1!B2;7;100;"")

Burada kullanılan 7 sayısı değiştirilecek karakterin başlangıç sayısıdır. 100 sayısı ise tahmini kullanılmış bir bitiş değeridir. B sütunundaki verinizin karakter sayısı ile bağıntılıdır.


Formülü yorumlarsak;

Sayfa1 B2 hücresindeki verinin 7. karakterinde itibaren 100 karakterlik bölümünü "" (boşluk) değeri ile değiştir sonucuna ulaşırız.

Sonuç olarak aşağıdaki değeri elde ederiz.

212431

Umarım açıklayıcı olmuştur.