Seçime uyan verilerin sayısına ulaşmak

[Korhan Ayhan]

İyi Akşamlar Değerli Forum Üyeleri,

Bu bölüme uzun süredir soru sormuyordum. Bir çalışma ile uğraşırken bu bölüme uygun olabileceğini düşündüm.

Konuyla ilgili alternatif cevapların iyi bir beyin fırtınası olacağını düşünüyorum.

Gelelim soruma;

Excel sayfalarında birkaç sütundan oluşan benzer tablolarım var.
Ana sayfamda belirlediğim sütunlardaki verilerden istediklerimi seçerek, seçime uyan kayıtların sayısını öğrenmek istiyorum. Seçim yaparken bir kısıtlama yoktur. 3 kriteri seçebileceğim gibi tek kriterde seçebilirim. Uygulanacak çözümün her şekilde sonuç vermesi gerekiyor.

Örnek dosya ektedir.

 

[1Al2Ver]

Merhaba,

Size uygun bir çözüm mü bilemedim ama basit bir yöntemle oldu sanırım.

 

[turist]

Alternatif dosya eklidir.

 

[Ömer BARAN]

Merhabalar Sayın AYHAN.

Ben olsam (makro olayına hakim olmadığımdan formül ile çözüm bulmak için;
BLOK sayfalarının F3 hücrelerine aşağıdaki formülü uygular ve aşağı doğru listeler boyunca kopyalardım.

=EĞER(EĞER(ÖZET!$B$2<>"";D3;"")&EĞER(ÖZET!$B$3<>"";C3;"")&EĞER(ÖZET!$B$4<>"";E3;"")=EĞER(ÖZET!$B$2<>"";ÖZET!$B$2;"")&EĞER(ÖZET!$B$3<>"";ÖZET!$B$3;"")&EĞER(ÖZET!$B$4<>"";ÖZET!$B$4;"");MAK($F$2:F2)+1;"")

Sonra da ÖZET sayfasında da E2 hücresine;

=MAK(DOLAYLI(E$1&"!$F$3:$F$9"))

formülünü uygulayıp sağa doğru çoğaltırdım.
Yanlış anlamadıysam bu şekilde sonuç alınabiliyor.

 

[Korhan Ayhan]

Değerli Arkadaşlar,

Amacımız yardımcı alan kullanmadan direkt mümkün olduğunca kısa bir formülle çözüme ulaşmaktır.

 

[Merhum İdris SERDAR]

.

E2 hücresine:

=IFERROR(SUMPRODUCT(COUNTIFS(INDIRECT("'"&E1&"'!D2:D20");$B$2;INDIRECT("'"&E1&"'!C2:C20");$B$3;INDIRECT("'"&E1&"'!E2:E20");$B$4));"")

yazıp. sağa doğru kopyalayın.

Dosya ekte.

Ayrıca, buradaki SUMIFS ile yapılan örnekler, bir fikir verebilir. COUNTIFS'e uyarlayabilirsiniz.

http://www.excelgurusu.com/3d-3b-sumifs-coketopla/


http://www.excelgurusu.com/3d-3b-sumif-etopla-3d-3b-sumifs-coketopla/


.

 

[Erdem Akdemir]

Korhan bey merhaba,

E2 hücresine,dizi formülüdür.

=TOPLA.ÇARPIM(--(EĞER($B$4="";SATIR($1:$7)^0;DOLAYLI("'"&E1&"'!E3:E9")=$B$4))*(EĞER($B$3="";SATIR($1:$7)^0;DOLAYLI("'"&E1&"'!c3:c9")=$B$3))*(EĞER($B$2="";SATIR($1:$7)^0;DOLAYLI("'"&E1&"'!d3:d9")=$B$2)))

 

[Ömer]

Merhaba,

Veri düzenine bakınca aranan ölçütlerin satır sırasıyla, sayfadaki aradığımız verilerin sütun sıraları farklı. Yalnız veri içerikleri birbiriyle tamamen farklı olduğu için sıranın önemini gözardı ederek hesaplama yapabiliriz. Sonucu değiştirmeyecektir.

Dizi formülü:

=TOPLA(--(DÇARP(EĞERSAY($B$2:$B$4;DOLAYLI("'"&E1&"'!C3:E9"))
 ;SATIR($B$2:$B$4)^0)=BAĞ_DEĞ_DOLU_SAY($B$2:$B$4)))

------------------------------------------------------------------------------

Eğer veri içerikleri benzerlik taşırsa yada sütunları birbirinden kopuksa, arama ölçütü ile aranan değerin sırasını düzenlemek formülü daha kullanışlı yapar. Değiştirme durumu yoksa aşağıdaki gibi basit mantıkla formülü yazabilirsiniz.

Aşağıdaki formülü tek sayfa varmış gibi yazdım, dolaylı eklemesini yapmadım.

=TOPLA.ÇARPIM(--(('1.BLOK'!D3:D9=B2)+('1.BLOK'!C3:C9=B3)+('1.BLOK'!E3:E9=B4)
 =BAĞ_DEĞ_DOLU_SAY(B2:B4)))

.

 

[Korhan Ayhan]

Merhaba Değerli Arkadaşlar,

İdris bey sizin önerinizde otel adını silince formül sıfır değerini veriyor.

Sayın Kuvari sizin önerinizde olumlu sonuç alabiliyorum.

Ömer Bey sizin önerinizde olumlu sonuç veriyor ve oldukça kısa bir formül oldu.

 

[Korhan Ayhan]

Sayın Kuvari sizin önerinizde olumlu sonuç alabiliyorum. Fakat kriterlerden birisini silince formül hata veriyor.

 

[Korhan Ayhan]

Arkadaşlar,

Çözüm önerilerini tek dosyada topladım. İlgilenenler inceleyebilirler.

Soruyu foruma sormadan önce kendi kullandığım çözüm aşağıdaki gibidir.

=EĞER(BAĞ_DEĞ_DOLU_SAY($B$2:$B$4)=0;0;TOPLA.ÇARPIM(--(EĞER($B$2="";"-";DOLAYLI("'"&E$1&"'!D3:D100"))&EĞER($B$3="";"-";DOLAYLI("'"&E$1&"'!C3:C100"))&EĞER($B$4="";"-";DOLAYLI("'"&E$1&"'!E3:E100"))=EĞER($B$2="";"-";$B$2)&EĞER($B$3="";"-";$B$3)&EĞER($B$4="";"-";$B$4))))

 

[Erdem Akdemir]

Sayın Kuvari sizin önerinizde olumlu sonuç alabiliyorum. Fakat kriterlerden birisini silince formül hata veriyor.

Korhan bey merhaba,

Dolaylı formülündeki hücre aralığını arttırdığınızda satır fonksiyonundaki aralığıda arttırmak gerekir.

=TOPLA.ÇARPIM(--(EĞER($B$4="";SATIR($1:$98)^0;DOLAYLI("'"&E1&"'!E3:E100")=$B$4))*(EĞER($B$3="";SATIR($1:$98)^0;DOLAYLI("'"&E1&"'!c3:c100")=$B$3))*(EĞER($B$2="";SATIR($1:$98)^0;DOLAYLI("'"&E1&"'!d3:d100")=$B$2)))

 

[Korhan Ayhan]

Haklısınız. Dikkatimden kaçmış.

Üstteki mesajımda ki dosyayı güncelliyorum.

 

[Korhan Ayhan]

Üstteki mesajımda ki dosyada hiçbir kriter seçimi yapılmadığında önerilen formüller hatalı sonuç veriyordu. Bu sorun giderilerek örnek çözüm dosyayı güncellenmiştir. İlgilenen üyelerimiz inceleyebilirler.