Son Kelİmeye Bakarak DeĞİŞİklİk

[excel_haso]

Merhaba arkadaşlar,

J kolonundaki hücrelerde bazen en az iki kelimelik textler var bazıları beş, bazı hücreler ise altı kelime, benim amacım J kolonundaki hücrelerin içinde ki cümlelerin son kelimesine göre değişiklik yapmak mesela

Hasan Atılcan Marmara
Uğur Gezen Top İzmir
Eğer son kelimesi Marmara ise K kolonuna 1, İzmir ise 2 yazsın istiyorum.

 

[hsayar]

1) Son kelimeler marmara ve izmir mi daima, bunun cevabı hazır birazdan eklerim
2) eğer değilse son kelimeyi nasıl bulabilirim sorusunun cevabını bulursam diğeri kolay...

 

[hsayar]

1)

 =EĞER(EĞERSAY(A1;"*"&"marmara")>0;1;EĞER(EĞERSAY(A1;"*"&"izmir")>0;2))

 

[Ali]

1) son kelimeyi nasıl bulabilirim sorusunun cevabını bulursam diğeri kolay...

Sn hsayar bu sizin daha önce söylediğiniz formül

 =SAĞDAN(A1;UZUNLUK(A1)-BUL("*";YERİNEKOY(A1;" ";"*";UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;" ";"")))))

Buda dizi formülü olan

=SAĞDAN(A1;UZUNLUK(A1)-MAK(SATIR(DOLAYLI("1:"&UZUNLUK(A1)))*(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" ")))

yazıp CTRL+SHIFT+ENTER tuşlarına birlikte basıp formül girişiniz tamamlayınız.

 

[hsayar]

vba olarak nasıl olacak, sadece arkadaş için sormuyorum banada lazım
=sonkelime(a1)

 

[excel_haso]

son kelimeler
istanbul
anadolu
diğer

 

[hsayar]

Merhaba arkadaşlar,

J kolonundaki hücrelerde bazen en az iki kelimelik textler var bazıları beş, bazı hücreler ise altı kelime, benim amacım J kolonundaki hücrelerin içinde ki cümlelerin son kelimesine göre değişiklik yapmak mesela

Hasan Atılcan Marmara
Uğur Gezen Top İzmir
Eğer son kelimesi Marmara ise K kolonuna 1, İzmir ise 2 yazsın istiyorum.

CEVAP

1)

 =EĞER(EĞERSAY(A1;"*"&"marmara")>0;1;EĞER(EĞERSAY(A1;"*"&"izmir")>0;2))

son kelimeler
istanbul
anadolu
diğer

istanbul için kaç yazacak
anadolu için kaç yazacak
diğer için kaç yazacak

ben 1,2,3 olarak yapacam sen değiştirirsin.
bu arada son kelimelerin bunlar değilmi daha artarsa iş vba ya kaçar haberin olsun

 

[excel_haso]

Aslında VBA olsa daha iyi olur

 

[hsayar]

=EĞER(SAĞDAN(A1;UZUNLUK(A1)-BUL("*";YERİNEKOY(A1;" ";"*";UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;" ";"")))))="istanbul";1;EĞER(SAĞDAN(A1;UZUNLUK(A1)-BUL("*";YERİNEKOY(A1;" ";"*";UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;" ";"")))))="anadolu";2;3))

a1 yazan hücreleri istediğin ile düzelt

son kelime fonksiyoınunu neden istediğim anlaşılmıştır sn ali görüldüğü üzere çok uzun

 

[excel_haso]

Teşekkür ederim böyle hallettim fakat VBA sı da olursa iyi olacak

 

[veyselemre]

vba olarak nasıl olacak, sadece arkadaş için sormuyorum banada lazım
=sonkelime(a1)

 Function sonkelime(gir As String)
    kelimeler = Split(gir)
    sonkelime = kelimeler(UBound(kelimeler))
End Function

 

[hsayar]

sayın veysel emre teşekkür ederim

sayın excel_haso formülüaşağıdaki gibi değiştiriniz

 =EĞER(SONKELİME(A1)="istanbul";1;EĞER(SONKELİME(A1)="anadolu";2;3))

Muhtemelen Ad hatası alacaksınız
Çalışmakta olduğunuz sayfanın üzerinde sağ tıklayın (örn: Sayfa1)
Kod Görüntüleye tıklayın
Çalışmakta olduğunuz excel dosyasını göreceksiniz (örn aaa.xls)
Üzerinde sağ tıklayın sırasıyla insert> module tıklayın

sayın veysel emrenin kodlarını yapıştırın

.

 Function sonkelime(gir As String)
    kelimeler = Split(gir)
    sonkelime = kelimeler(UBound(kelimeler))
End Function