Sütunlarda yer alan verileri Satırlara dağıtmak

[tug@y]

Merhabalar,

Müşterimizden 1.tabloda yer alan şekilde sipariş gelmektedir. Kendi sistemimize yüklemek 2.Tabloda yer alan Mağaza, Ürün, Adet olacak şekilde dönüştürmek istiyorum.
Tabi sipariş mağazası veya ürün satırı az olunca manuel bir şekilde alt alta yapıştırıyorum ama çok mağaza ve ürün olunca çok vakit alıyor. Yardımcı olabilir misiniz?


1.Tablo

Ürün	İstanbul Mağaza	Ankara Mağaza	Antalya Mağaza
X-Ayakkabı	10​	20​	10​
Y-Terlik	10​	20​	10​

2.Tablo

Mağaza	Ürün	Adet
İstanbul Mağaza	X-Ayakkabı	10​
İstanbul Mağaza	Y-Terlik	10​
Ankara Mağaza	X-Ayakkabı	20​
Ankara Mağaza	Y-Terlik	20​
Antalya Mağaza	X-Ayakkabı	10​
Antalya Mağaza	Y-Terlik	10​

 

[52779]

Excel365 kullanıcısı olduğunuzdan,
Excel365 işlevleriyle çözüm

Örnek olarak
Verileriniz
a : Ürünler : A2 : A6
b : Mağazalar : B1 : D1
c : Adetler : B2 : D6
aralığında olup bazı adet değerleri BOŞ hücre olsun.

F2 hücresine (ya da herhangi BOŞ hücreye) aşağıdaki formül yazılır. Sonuçlar dökülmeli olarak gelir.
(Not : Dökülme alanı BOŞ olmalıdır. Başka bir veri ya da birleştirilmiş hücreler olmamalıdır)

=LET(a;A2:A6;b;B1:D1;c;B2:D6;YATAYYIĞ(SÜTUNA(EĞER(c<>"";b;1/0);3;1);SÜTUNA(EĞER(c<>"";a;1/0);3;1);SÜTUNA(c;3;1)))

Formülde bulunan, a, b, c parametrelerindeki (koyu yazılanlar) hücre aralıklarını dosyanıza göre uyarlamak yeterli olacaktır.

​	A​	B​	C​	D​	​	F​	G​	H​
1​	Ürün​	İstanbul Mağaza​	Ankara Mağaza​	Antalya Mağaza​	​	Mağaza​	Ürün​	Adet​
2​	X-Ayakkabı​	10​	20​	10​	​	İstanbul Mağaza	X-Ayakkabı	10​
3​	Y-Terlik​	10​	20​	10​	​	İstanbul Mağaza	Y-Terlik	10​
4​	Z-Bot​	​	12​	​	​	İstanbul Mağaza	K-Çizme	5​
5​	K-Çizme​	5​	​	6​	​	Ankara Mağaza	X-Ayakkabı	20​
6​	M-Spor​	​	​	7​	​	Ankara Mağaza	Y-Terlik	20​
						Ankara Mağaza	Z-Bot	12​
						Antalya Mağaza	X-Ayakkabı	10​
						Antalya Mağaza	Y-Terlik	10​
						Antalya Mağaza	K-Çizme	6​
						Antalya Mağaza	M-Spor	7​

 

[tug@y]

Elinize sağlık, çook teşekkürler

 

[52779]

Ben teşekkür ediyorum.
Yardımcı olabildiğime sevindim.