sutunlara göre icerik temizleme

[sebahattin]

Selam ün Aleykum ustadlar öncellikle sizlere bir teşekkür etmek lazım .Yine Sizlerden yârdim isteyeceğiz ekte sunduğumuz Excel dosyasında bazı sutunlardan yazlan verileri bir makro yardimıyle iceregi temizlemek istıyoruz silecegimiz sutunlar Sirası ile söyle(B-G-H-K-L-M-P-S-T-U-V-) Bu sütünların İceriğini silerken bana bir sifre sorsun sifrem (KHV413441)Bu sifreyı kullanıcı girdiğinde bu sütunlardaki bilgileri temizlemesini istıyoruz bunu yapmak mümkunmudur tesekkurler

Ekli dosyalar

 

[Korhan Ayhan]

Deneyiniz.

Option Explicit

Sub Clear_Columns()
    Dim My_Password As Variant, My_Area As Range, Approval As Byte
    
    My_Password = InputBox("Lütfen şifrenizi giriniz...")
    
    If My_Password = False Or My_Password = "" Then Exit Sub
    
    If My_Password = "KHV413441" Then
        Approval = MsgBox("Tanımlı sütunların içeriği temizlenecektir. İşlemi onaylıyor musunuz?", vbCritical + vbYesNo + vbDefaultButton2)
        If Approval = vbNo Then
            MsgBox "İşlem onayını doğrultusunda iptal edilmiştir.", vbInformation
            Exit Sub
        End If
        Set My_Area = Union(Range("B8:B1048576"), Range("G8:H1048576"), Range("K8:M1048576"), Range("P8:P1048576"), Range("S8:V1048576"))
        Application.ScreenUpdating = False
        Application.EnableEvents = False
        My_Area.ClearContents
        Application.EnableEvents = True
        Application.ScreenUpdating = True
        MsgBox "Tanımlı alanın içeriği temizlenmiştir.", vbInformation
    Else
        MsgBox "Hatalı şifre girdiğiniz için işlem iptal edilmiştir.", vbExclamation
    End If
End Sub

 

[sebahattin]

Hocam teşekkürler yalnız mesaj kısmı na şöyle bir şey eklemek istiyoruz şifreyi girdikten sornra mesajla içeriği temizlemek istiyorum evet veya hayır sorusunu sormasını evet dersek içeriği silsin hayır dersek içeriği silmesin diye kullaciyi yonlendirmesini istiyoruz munkunmu

 

[Korhan Ayhan]

Kodu revize ettim. Tekrar deneyiniz.

 

[sebahattin]

HOCAM TESEKKURLER TAMAMDIR ALLAH RAZI OLSUN SİZLERDEN