TABLOLARDA SAYFA KORUMASI

[ThaLees]

Merhabalar
Ekteki excelde örneklendirmeye çalıştığım bir tablom var. Formül olan hücrelere erişimi kapatmak için sayfa korumasını aktif hale getiriyorum.
Bilindiği gibi tablolarda en sağ-alt hücrede TAB tuşuna bastığımızda alta otomatik olarak formüller ile birlikte yeni bir satır ekleniyor. Lakin sayfa kormasını aktif hale getirdiğimde bu satır ekleme işlemi maalesef olmuyor. Bunu nasıl yapabilirim ?

Not : Örnekte sayfa koruması aktif ve herhangi bir parola yoktur.

Şimdiden yardımcı olamaya çalışan herkese teşekkürler

 

[Seyit Tiken]

İstediğiniz böyle bir şey mi?

 

[Korhan Ayhan]

Talebiniz makro ile yapılabilir gibi görünüyor.

Aşağıdaki kodları uygulayıp deneyiniz. Dosyanızı kaydedip, kapatıp açın.

Ctrl+Tab tuşuna bastığınızda satır ekleme işlemi otomatik gerçekleşecektir.

ThisWorkbook bölümüne;

Option Explicit

Private Sub Workbook_Activate()
    Application.OnKey "^{TAB}", "Satir_Ekle"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.OnKey "^{TAB}"
End Sub

Private Sub Workbook_Deactivate()
    Application.OnKey "^{TAB}"
End Sub

Private Sub Workbook_Open()
    Application.OnKey "^{TAB}", "Satir_Ekle"
End Sub

Boş bir modüle;

Option Explicit

Sub Satir_Ekle()
    Dim Bul As Range
   
    With Sheets("Sayfa1")
        .Unprotect
        With .ListObjects("Tablo2")
            Set Bul = .Range.Columns(.ListColumns.Count).Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious)
            If Not Bul Is Nothing Then
                Bul.Offset(-1, 0).ListObject.ListRows.Add AlwaysInsert:=False
            End If
        End With
        .Protect
    End With

    Set Bul = Nothing
End Sub