Tabloya yeni eklenen kayıtların otomatik listesi

[aydefdem]

Herkese merhaba,

Ekteki dosyada her ay farklı verilen olduğu bir mizan sayfası var (TRREP_MIZAN GÜNCEL). Birde ana bir liste var(TRREP_MIZAN). Her ay yeni hesaplar ay içinde açılabiliyor. Dosyada normalde çok sayıda yeni hesap oluyor ama örnek olsun diye yeni 2 hesabı sarı renk ile işaretledim. İsteğim şudur; Bu ay eklenen kayıtları yani Ana tabloda olmayan kalemleri tek bir liste halinde çıkaracak şekilde bir tablo oluşsun.

Yardımlarınız için şimdiden teşekkür ederim.

 

[veyselemre]

Sub test()
    Dim veri, dic, i, say

    With Sheets("TRREP_MIZAN")
        veri = .Range("A7:A" & .Cells(Rows.Count, 1).End(3).Row).Value
    End With
    Set dic = CreateObject("Scripting.Dictionary")

    For Each i In veri
        dic.Item(i) = Null
    Next i

    With Sheets("TRREP_MIZAN GÜNCEL")
        veri = .Range("A7:B" & .Cells(Rows.Count, 1).End(3).Row).Value
        For i = 1 To UBound(veri)
            If Not dic.exists(veri(i, 1)) Then
                say = say + 1
                veri(say, 1) = veri(i, 1)
                veri(say, 2) = veri(i, 2)
            End If
        Next i
    End With
    If Evaluate("ISREF('" & "Bulunmayanlar" & "'!A1)") = False Then Sheets.Add(, Sheets(Sheets.Count)).Name = "Bulunmayanlar"
    With Sheets("Bulunmayanlar")
        .Cells.ClearContents
        .Cells(1, 1).Resize(say, 2).Value = veri
        .Columns.AutoFit
    End With

End Sub

 

[aydefdem]

Merhaba,

Yardımınız için çok teşekkür ederim. Makroyu kopyaladım önce çalıştı ama kaydederken "dikkat belgenizin bazı bölümleri belge denetçisi tarafından bilgiler içeriyor olabilir" uyarısı çıktı. Onu ayarlardan hallettim. Ama makro bilgimin zayıflığından dolayı sanırım tekrar dosyadan çıkıp girdiğimde makroyu göremiyorum. Bir de her seferinde makroyu tekrar çalıştır mı demem lazım.

Saat biraz geç oldu kusura bakmayın. Uygun bir saate yardımlarınızı tekrar rica ediyorum.