Toplam değeri dağıtarak düşürme

[patronos]

Merhaba aşağıdaki görseldeki gibi bir sonuç elde etmem lazım E2 de belirttiğim gibi D2 deki ürün kodundan 10 adet iade düşmesi gerekiyor ve bunu en yüksek değerden başlayarak düşürmesi gerekiyor.

Bunu nasıl yaparım, yardımcı olursanız çok sevinirim

 

[52779]

Excel365 kullanıcısı olduğunuzdan Excel365 işlevleriyle çözüm...
(Klasik formüllerle ???)

C2 hücresine formül yazılır ve sonuçlar dökülmeli gelir.

=LET(a;A2:A24;b;B2:B24;c;E2;d;F2;e;SATIR(a);f;SIRALA(FİLTRE(YATAYYIĞ(e;b);a=c);2;-1);g;İNDİS(f;;2);h;SCAN(0;g;LAMBDA(x;y;TOPLA(x;y)));k;EĞER(h<d;0;EĞER(h-d>g;g;g-h+d));EĞERHATA(ÇAPRAZARA(e;İNDİS(f;;1);k);b))

Not : formüldeki Koyu yazılan ilk parametreler (a, b, c ve d parametreleri) hücreler ve hücre aralıklarıdır. Dokumanınıza uygun olarak, bu aralıkları düzenlemek yeterli olacaktır.

​	A​	B​	C​	D​	E​	F​
1​	Ürün kodu​	Satış Adet​	Hesaplama​		Ürün Kodu​	Azaltılacak​
2​	58945678​	4​	4​		12345678​	27​
3​	12345678​	5​	0​	4. Büyük 5 < 6... 5 - 5 = 0 ve Kalan 6 - 5 = 1
4​	12345678​	5​	1​	5. Büyük 5 > 1... 5 - Kalan (4) = 1 ve Kalan YOK.
5​	12345678​	5​	5​	6. Büyük... Kalan olmadığından Değeri AYNI
6​	23456789​	8​	8​
7​	23456789​	4​	4​
8​	12345678​	5​	5​	7. Büyük... Kalan olmadığından Değeri AYNI
9​	12345678​	6​	0​	2. Büyük 6 < 18... 6 - 6 = 0 ve Kalan 18 - 6 = 12
10​	12345678​	4​	4​	8. Büyük... Kalan olmadığından Değeri AYNI
11​	12345678​	6​	0​	3. Büyük 6 < 12... 6 - 6 = 0 ve Kalan 12 - 6 = 6
12​	23456789​	5​	5​
13​	23456789​	4​	4​
14​	23456789​	7​	7​
15​	34567890​	8​	8​
16​	34567890​	6​	6​
17​	34567890​	4​	4​
18​	12345678​	3​	3​	9. Büyük... Kalan olmadığından Değeri AYNI
19​	12345678​	9​	0​	1. Büyük... 9 < 27... 9 - 9 = 0 ve Kalan 27 - 9 = 18
20​	23456789​	1​	1​
21​	45678901​	7​	7​
22​	45678901​	8​	8​
23​	45678901​	5​	5​
24​	12345678​	2​	2​	10. Büyük... Kalan olmadığından Değeri AYNI