Vba ile Rapor alma

[a_self_lion]

Selam Arkadaşlar, Sizlerin yardımıyla kendime çok güzel bir irsaliye takip programı yaptım bir firma ile başımız dertte günlük gelen ürünleri hep sorunlu ya geliyor ya gelmiyor fazla fatura ediyorlar vb.. Bunların önünüe geçebilmek için bende kendime işte sizlerinde yardımıyla bir takip sistemi kurdum.

Ama burda da rapor alırken yine vb ya ihtiyacım Bu konuda da yardımlarınızı esirgemiyeceğinizi umuyorum.

Veri sayfasındaki verilerim üzerinde B sutunu tarih D sutunu Mlz_Kod G sutunu Miktar J sutunu Toplam Tutar L sutunu Kdv Tutarı ve M sutunu Kdvli Toplam dır.

Benim yapmak istediğim Macro ile B sutunundaki benim girdiğim tarih aralığında verileri bulup D sutunundaki mlz_kod ları ilk girişten yazarak benzeri varsa ona ilave ederek Diyelim ki 01/08/2007 ile 07/08/2007 tarihleri arasında M OE 3045 ÜRÜNÜ RAPOR SAYFASINA YAZSIN A1 E YAZSIN B1 E mlz_adi C1 MİTARI D1 E TOPLAM TUTAR E1 İSK.TUTAR F1 E KEV TUTARI G1 E KDVLİ TOPLAM yazsın ve aşağı doğru yine M OE 3045 ÜRÜNÜ VARSA BUNLARIN ÜZERİNE TOPLAYARAK YAZSIN DİĞERLERİ DE AYNI MANTIKLA ALT ALTA DEVAM ETSİN
Bunu yapmak sanırım mümkün ama ben nasıl yapacağımı bilemiyorum. Yardım ederseniz çok sevenirim.
örnek dosyamı da ekliyorum.

 

[Recep İpek]

Rapor sayfasına birkaç malzeme kodu için olmasını istediğiniz sonuçları yazabilirmisiniz?

 

[a_self_lion]

yazıyorum hemen

 

[a_self_lion]

Sayın Ripek istediğiniz gibi örnek dosyayı benim istediğim gibi düzenleyerek ekledim.

 

[Recep İpek]

Aşağıdaki kodları kullanabilirsiniz.

Sub AktarTopla()
Dim a, i As Long, b(), n As Long
Set s1 = Sheets("veri")
Set s2 = Sheets("rapor")
With s1.Range("a2:m" & s1.[a65536].End(3).Row).Resize(, 13) 'veri sayfasındaki a2 ile a kolonundaki son satırdan sağdaki 13 kolonu
     a = .Value ' a değişkenine atanıyor.
     ReDim b(1 To UBound(a, 1), 1 To 8) 
End With
With CreateObject("Scripting.Dictionary") 'Dictionary nesnesi oluşturuluyor.
    .CompareMode = vbTextCompare
    For i = 1 To UBound(a, 1)
        If CDate(a(i, 2)) >= CDate([K2]) And CDate(a(i, 2)) <= CDate([L2]) Then ' a değişkenindeki 2.kolonun tarihi belirttiğiz tarih aralığında ise
            If Not .exists(a(i, 4)) Then ' ve a değişkenindeki 4. kolon malzeme kodu yok ise, yani teke düşürüyoruz.
                n = n + 1
                b(n, 1) = n  ' Dizinin 1.elemanına Sıra No
                b(n, 2) = a(i, 4) 'Dizinin 2.elemanına Malzeme Kodu
                .Add a(i, 4), n 'Dictionary nesnesine kontrol için Malzeme No 
                b(n, 3) = a(i, 5) 'Dizinin 3 elemanına Malzeme Adı
            End If
                b(.Item(a(i, 4)), 4) = b(.Item(a(i, 4)), 4) + a(i, 7) 'malzeme kodu var ise l ise 
                b(.Item(a(i, 4)), 5) = b(.Item(a(i, 4)), 5) + a(i, 10) ' diğer alanların toplamını alıyoruz.
                b(.Item(a(i, 4)), 6) = b(.Item(a(i, 4)), 6) + a(i, 11) '....
                b(.Item(a(i, 4)), 7) = b(.Item(a(i, 4)), 7) + a(i, 12)
                b(.Item(a(i, 4)), 8) = b(.Item(a(i, 4)), 8) + a(i, 13)
        End If
     Next
End With
s2.Range("a2:m" & s2.[a65536].End(3).Row).Resize(, 8).ClearContents
s2.[a2].Resize(n, 8).Value = b
MsgBox "Bitti"
s2.Select
[a1].Select
Set s1 = Nothing
Set s2 = Nothing
End Sub

 

[a_self_lion]

Sayın ripek Çok Çok teşekkür ederim. Tam istediğim gibi olmuş. Bu hem işimi gördü hemde diğer çalışmalarım için örnek teşkil edecek. Sizden Allah razı olsun. Bu arada Bütün arkadaşların Kandilleri Mübarek olsun.

 

[a_self_lion]

Sayın Ripek Daha sonraki çalışmalarımıza daha iyi anlayarak örnek teşkil etmesi için kısa açıklamalar yazabilirseniz benim anlamam daha kolay olacak. Ezbere yapmamış oluruz. Zamanınız varsa tabi. Teşekkürler.

 

[Recep İpek]

Açıklama bilgileri yanlarına eklenmiştir.

 

[a_self_lion]

Sayın Ripek çok teşekkür ederim. Elinize sağlık