verileri kaydetme

[masi]

iki konuda yardıma ihtiyacım var.

konu 1 : Sayfa3 bulunan Kaydet/Yazdır Butonuna basıldığında,

Yine sayfa3 bulunan, b2-b4-b6-b8-b10-b12 verilerinin, sayfa4'e yatay olarak sırasıyla a2-b2-c2 .... olarak nasıl aktarabilirim.

Yine sayfa3 bulunan f2-g2-h2-ı2-j2-k2-L2-m2 verilerinin sayfa5'e yatay olarak sırasıyla a2-b2-c2 .... olarak nasıl aktarabilirim.

burada kaydet butonu hem sayfa4 veri aktaracak hem de sayfa5 verilerini aktaracak.



Konu 2 :

Private Sub CommandButton1_Click()
Sheets("sayfa1").Range("b1:b6").Copy
sat = Sheets("sayfa2").Cells(65536, "A").End(xlUp).Row + 1
Sheets("sayfa2").Range("A" & sat).PasteSpecial
Application.CutCopyMode = False
MsgBox "ÜRÜN EKLENDİ..!!"

End Sub

böyle bir kodu kullanıyorum. fakat ben sayfa2 girilen verileri a1:a6 değil de, yatay olarak a1,b1,c1 .... olarak veri girmesini istiyorum nasıl düzenleme yapılabilir.

şimdiden teşekkürler

 

[dEdE]

Merhaba,
Konu1 sorunuz için;

Sub Kaydet_Yazdır()
    Sheets("Sayfa3").Range("F2:M2").Copy Sheets("Sayfa5").Range("A2")
    Sheets("Sayfa3").Range("B2:B12").SpecialCells(xlCellTypeConstants, 23).Copy
    Sheets("Sayfa4").Range("A2").PasteSpecial Paste:=xlPasteAll, SkipBlanks:=False, Transpose:=True
    Application.CutCopyMode = False
End Sub

Konu2 sorunuz için;

Private Sub CommandButton1_Click()
    Sheets("Sayfa1").Range("B1:B6").Copy
    Sheets("Sayfa2").Range("A1").PasteSpecial Paste:=xlPasteAll, Transpose:=True
    Application.CutCopyMode = False
    MsgBox "ÜRÜN EKLENDİ..!!"
End Sub

Hoşçakalın.

 

[masi]

Hocam, öncelikle emeğinizden dolayı teşekkür ederim.
iki hata alıyorum.
1) Sheets("Sayfa3").Range("F2:M2").Copy Sheets("Sayfa5").Range("A2") bilgileri sayfa5 aktarıyor . yeni kayıt girdiğimde aynı satıra kaydediyor.
Sheets("Sayfa4").Range("A2").PasteSpecial Paste:=xlPasteAll, SkipBlanks:=False, Transpose:=True elinize sağlık harika olmuş, fakat tekrar yeni kayıt girdiğimde aynı satıra ekleme yapıyor. bir sonra ki satıra yazmıyor.

2)
Private Sub CommandButton1_Click()
Sheets("Sayfa1").Range("B1:B6").Copy
Sheets("Sayfa2").Range("A2").PasteSpecial Paste:=xlPasteAll, Transpose:=True
Application.CutCopyMode = False
MsgBox "ÜRÜN EKLENDİ..!!"
End Sub

burada ki kod da yine yeni kayıt girildiğinde aynı satıra ekliyor. bir alt satıra ekleme yapmak için yardımlarınızı beklemekteyim.

Saygılarımla

 

[dEdE]

Merhaba,
1. nolu mesajınızı tekrar dikkatle okudum. 3 nolu mesajınızda istediğiniz anlamı çıkaramadım. Sanki soru eksik gibi !

Private Sub CommandButton1_Click()
    ss2 = Sheets("Sayfa2").Cells(Rows.Count, "A").End(xlUp).Row + 1
    If Sheets("Sayfa2").Cells(1, 1) = "" Then ss2 = 1
    Sheets("Sayfa1").Range("B1:B6").Copy
    Sheets("Sayfa2").Cells(ss2, 1).PasteSpecial Paste:=xlPasteAll, Transpose:=True
    Application.CutCopyMode = False
    MsgBox "ÜRÜN EKLENDİ..!!"
End Sub

Sub Kaydet_Yazdır()
    ss5 = Sheets("Sayfa5").Cells(Rows.Count, "A").End(xlUp).Row + 1
    Sheets("Sayfa3").Range("F2:M2").Copy Sheets("Sayfa5").Cells(ss5, 1)
    ss4 = Sheets("Sayfa4").Cells(Rows.Count, "A").End(xlUp).Row + 1
    Sheets("Sayfa3").Range("B2:B12").SpecialCells(xlCellTypeConstants, 23).Copy
    Sheets("Sayfa4").Cells(ss4, 1).PasteSpecial Paste:=xlPasteAll, SkipBlanks:=False, Transpose:=True
    Application.CutCopyMode = False
End Sub

 

[masi]

Hocam, elinize emeğinize sağlık. Harika oldu. Sayenizde iyi bir deneyim sahibi oluyoruz.