Excel Ajanda

[ekremmk]

Sayfa1 a1 hücresi idman a2 hücresi tarih a3 hücresi saat
Tarih ve saat geldiğinde excel mümkünse kapalıyken mümkün değilse açıkken İdman adlı bir bildirim oluşturabilir miyiz çok denedim ama başaramadım

 

[Korhan Ayhan]

Dosyanıza boş bir modüle ekleyin. Sonra aşağıdaki kodu uygulayın.

Dosyanızın açık olması gerekiyor.

Dosyanızı "Makro İçerebilen Excel Çalışma Kitabı" biçiminde kayıt edin. Sonra kapatıp açın. Dosya açıldığında ve makroları etkinleştirdiğinizde işlem başlayacaktır.

Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Function PlaySound Lib "winmm.dll" _
    Alias "PlaySoundA" (ByVal lpszName As String, _
    ByVal hModule As LongPtr, ByVal dwFlags As Long) As Long
#Else
    Private Declare Function PlaySound Lib "winmm.dll" _
    Alias "PlaySoundA" (ByVal lpszName As String, _
    ByVal hModule As Long, ByVal dwFlags As Long) As Long
#End If

Sub Auto_Open()
    Dim S1 As Worksheet
    
    Set S1 = Sheets("Sayfa1")
    
    DoEvents
    Calculate
    
    If Date = S1.Range("A2") Then
        If Time = S1.Range("A3") Then
            If Excel.Application.WindowState = xlMinimized Then Excel.Application.WindowState = xlMaximized
            Call PlaySound(ThisWorkbook.Path & "\Alarm01.wav", 0&, &H1 Or &H20000)
            MsgBox "İdman saatiniz geldi..." & vbLf & vbLf & _
                   "Yapılacak idman ; " & S1.Range("A1"), vbInformation
        End If
    End If
    
    Set S1 = Nothing
    
    Application.OnTime Now + TimeSerial(0, 0, 1), "Auto_Open"
End Sub

 

[ekremmk]

Dosyanıza boş bir modüle ekleyin. Sonra aşağıdaki kodu uygulayın.

Dosyanızın açık olması gerekiyor.

Dosyanızı "Makro İçerebilen Excel Çalışma Kitabı" biçiminde kayıt edin. Sonra kapatıp açın. Dosya açıldığında ve makroları etkinleştirdiğinizde işlem başlayacaktır.

Option Explicit

Sub Auto_Open()
    Dim S1 As Worksheet
 
    Set S1 = Sheets("Sayfa1")
 
    DoEvents
 
    If Date = S1.Range("A2") Then
        If Time = S1.Range("A3") Then
            MsgBox "İdman saatiniz geldi..." & vbLf & vbLf & _
                   "Yapılacak idman ; " & S1.Range("A1"), vbInformation
        End If
    End If
 
    Set S1 = Nothing

    Application.OnTime Now + TimeSerial(0, 0, 1), "Auto_Open"
End Sub

Emeğiniz için teşekkür ederim hocam. Kod çalışıyor. Bu kod üzerine gerekli oynamaları yapabilirim sanırım. Ama bir kaç sorum olacak müsadenizle Bildirim olarak sesli uyarı yapma şansımız var mı acaba dosya açıkken ama simge durumundayken sadece yanıp sönüyor bildirim dosyaya basınca çıkıyor basmadan bildirimi direkt zaman geldiğinde göre bilir miyiz?

 

[Korhan Ayhan]

Üstte ki mesajımı ve dosyayı revize ettim. Ne kadar verim alacaksınız bilemiyorum.

Bu dosyanın bulunduğu klasöre "Alarm01.wav" isimli dosyayı kopyalayıp ses çalmasını sağlayabilirsiniz. Siz farklı bir "wav" dosyasıda kullanabilirsiniz.

 

[ekremmk]

Üstte ki mesajımı ve dosyayı revize ettim. Ne kadar verim alacaksınız bilemiyorum.

Bu dosyanın bulunduğu klasöre "Alarm01.wav" isimli dosyayı kopyalayıp ses çalmasını sağlayabilirsiniz. Siz farklı bir "wav" dosyasıda kullanabilirsiniz.

Teşekkür ederim hocam kod gayet güzel çalışıyor. Bir kaç bir şey istiyorum programda kendim yapmaya çalışayım sizi yormamak için beceremezsem buradan yazarım müsait olduğunuzda cevaplarsanız çok sevinirim.