Soru Bütçe Birleşim hk.

[nazifdural]

Merhabalar,
Tablomda, "A" ile başlayan diğer sayfalardaki verileri "01-OTELBUTCE2023" sayfasındaki formata göre bu sayfaya alt alta makro ile getirmek istiyorum.
Not : A ile başlayan sayfalara verileri sorguyla alıyorum.
Yardımcı olursanız çok sevinirim.

 

[ÖmerFaruk]

Kod içindeki yeşil renkli açıklama satırına dikkat edin.
Kodu bir Module içine ekleyip kullanabilirsiniz.

Sub OtelButce()
    Dim Sh As Worksheet, Veri, Liste, Say As Long, i As Long, k As Byte
    ReDim Liste(1 To Rows.Count, 1 To 5)
    Worksheets("01-OTELBUTCE2023").Range("A4:E" & Rows.Count).ClearContents
    For Each Sh In Worksheets
        'If Sh.Name <> "01-OTELBUTCE2023" Then
        If Left(Sh.Name, 5) Like "A###-" Then 'Sayfa adının ilk 5 karakterine bakıyorum
            Veri = Sh.Range("A1").CurrentRegion.Value
            For i = 2 To UBound(Veri)
                If Veri(i, 1) = "" Then Exit For
                For k = 4 To 15
                    'Eğer tutar SIFIR olan bütçe kalemlerini ana sayfaya almayacaksanız
                    'aşağıdaki satırın başındaki tırnak işaretini silin
                    'If Veri(i, k) = 0 Then GoTo Devam
                    Say = Say + 1
                    Liste(Say, 1) = Veri(i, 1)
                    Liste(Say, 2) = Veri(i, 2)
                    Liste(Say, 3) = Veri(i, 3)
                    Liste(Say, 4) = Veri(1, k)
                    If Veri(i, k) = "-" Then
                        Liste(Say, 5) = 0
                    Else
                        Liste(Say, 5) = Replace(Veri(i, k), ".", "") * 1
                    End If
Devam:
                Next k
            Next i
        End If
    Next Sh
    Worksheets("01-OTELBUTCE2023").Range("A4").Resize(Say, 5) = Liste
    Erase Veri: Erase Liste
End Sub

 

[nazifdural]

Hocam çok sağolun birde A sayfalarından gelen Tutar kolonunu sayı formatına dönüştürerek getirmek mümkün mü? kolonda bazı sayılar metin olarak saklanan sayı formatında geliyor.

 

[nazifdural]

Hocam mükerrer kayıt getiriyor. Çalıştırdığım dosya ektedir.

 

[ÖmerFaruk]

Hocam çok sağolun birde A sayfalarından gelen Tutar kolonunu sayı formatına dönüştürerek getirmek mümkün mü? kolonda bazı sayılar metin olarak saklanan sayı formatında geliyor.

Siz verileri başka bir programdan çektiğinizi söylüyorsunuz. Ama bazı verileri sayı olarak çekmiş bazılarını metin olarak çekmişsiniz.
Gönderdiğiniz son dosyadaki A100-GONBURO sayfasınında Nisan Ekim arası tutarlar metin formatında. Kodda bununla ilgili revizeyi yaptım.

Mükerrer kayıt sizin tablolarınızda var.
Örneğin A100-GINBURO 29.satır ile GELİRBİRLEŞİM 29.satırlar aynı veriye sahip.

Eğer GelirBirleşim sayfası alınmayacak, sadece Axxx- ile başlayan sayfalara bakacağım diyorsanız kodu revize edebilirim. Ki ettim.
#2 nolu mesajdaki revize edilmiş halini kullanabilirsiniz.

 

[nazifdural]

Hocam elinize sağlık. Çok teşekkür ederim. Tam istediğim gibi oldu.
Allah size ve excel.web.tr ekibine sağlık sıhhat ve nice güzel başarılar versin.

 

[ÖmerFaruk]

Güzel temennileriniz için biz teşekkür ederiz.