Command Buton ile formüllerdeki sayfa ismi değiştirme

[HAKANP]

Arkadaşlar herkese selamlar,

Genel adı altında bir excel sayfasında

=TOPLA.ÇARPIM((('24.12.2008'!G7:G286=$C$3)*('24.12.2008'!K7:K286=B5))*('24.12.2008'!O7:O286=2))

şeklinde formüllerim var.

Formül içindeki '24.12.2008' değeri çalışma kitabındaki diğer sayalardan biri ve tarih tarih birçok sayfam var.

Ben Genel sayfasına koyacağım bir command buton ile a1 hücresine hangi tarihi yazar isem, Genel sayfasındaki tüm formüllerin içindeki sayfa isminin a1 hücresinde yazan tarih olmasını istiyorum.

Şayet Command.Buton' a gerek yok ise, formül içindeki tarih şeklindeki sayfa ismini a1 hücresinden nasıl aldırabilirim.

Şimdiden teşekkürler.

 

[Korhan Ayhan]

Selamlar,

İstediğiniz işlemi DOLAYLI fonksiyonu ile kolaylıkla çözümleyebilirsiniz.

Aşağıdaki formülü denermisiniz.

=TOPLA.ÇARPIM(((DOLAYLI($A$1&"!G7:G286")=$C$3)*(DOLAYLI($A$1&"!K7:K286")=B5))*(DOLAYLI($A$1&"!O7:O286")=2))

Ayrıca eğer A1 hücresine tarih yazacaksanız formülü aşağıdaki şekilde kullanınız.

=TOPLA.ÇARPIM(((DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!G7:G286")=$C$3)*(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!K7:K286")=B5))*(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!O7:O286")=2))

 

[HAKANP]

Yanıtınız için çok teşekkür ederim.
Peki aynı uygulamayı aşağıdaki formül için nasıl uygularım ?
=TOPLA(EĞER('24.12.2008'!$G$7:$G$286=$C$3;EĞER('24.12.2008'!$K$7:$K$286=B5;EĞER('24.12.2008'!$O$7:$O$286=2;'24.12.2008'!$N$7:$N$286;0);0);0))

Birde her iki formülün de değerleri "0" ise hiçbir şey yazmamasını, yani boş gelmesini istiyorum

 

[Korhan Ayhan]

Selamlar,

Kullandığınız formülü aşağıdaki şekilde deneyiniz.

=TOPLA(EĞER(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$G$7:$G$286")=$C$3;EĞER(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$K$7:$K$286")=B5;EĞER(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$O$7:$O$286")=2;DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$N$7:$N$286");0);0);0))

Sıfır değerlerinin görünmemesi için;

ARAÇLAR-SEÇENEKLER-GÖRÜNÜM menüsünü açın.
Alt kısımda "Sıfır Değerleri" seçeneğini pasif duruma getirip tamam dediğinizde sıfır yazan hücrelerdeki sıfırlar görüntü olarak kaybolacaktır.

 

[HAKANP]

Selamlar,

Kullandığınız formülü aşağıdaki şekilde deneyiniz.

=TOPLA(EĞER(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$G$7:$G$286")=$C$3;EĞER(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$K$7:$K$286")=B5;EĞER(DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$O$7:$O$286")=2;DOLAYLI(METNEÇEVİR($A$1;"gg.aa.yyyy")&"!$N$7:$N$286");0);0);0))

Sıfır değerlerinin görünmemesi için;

ARAÇLAR-SEÇENEKLER-GÖRÜNÜM menüsünü açın.
Alt kısımda "Sıfır Değerleri" seçeneğini pasif duruma getirip tamam dediğinizde sıfır yazan hücrelerdeki sıfırlar görüntü olarak kaybolacaktır.

Yanlız "0" değerleri için yapmamızı istediğiniz bu değişiklik sadece bu çalışma sayfasına özel bir şey olmalı, başka çalışma kitaplarında uygulanmamalı.

 

[Korhan Ayhan]

Selamlar,

Bu durumda sıfır gözükmesini istemediğiniz hücreleri seçip hücre biçimlendirmesini aşağıdaki şekilde ayarlayınız.

[=0]"";Genel

 

[HAKANP]

Emeği geçen herkese, herşey için çok süper teşekkürler.

Bu konu başlığı üzerindeki sorularım bitmiştir.

Yeni bir Konu başlığında çok iddialı bir sorum olacak.

Belkide hiç istenememiş birşeydir.

Eminim çözümü halinde birçok kişinin işine yarar.

Koşullu toplam üzerinden sayılan değerlerin, açıklamaya eklenerek listelenmesi