Bulduğu hücrenin yanına işaret koymak

[TheDarkness]

Merhaba

Tüm çalışma kitabında (SAYFA1.Sayfa2.sayfa3…..) CTRL+F İLE aradığım veriyi bulduğunda, buldugu hücrenın yanına " * " işaretini koymasını istiyorum.Örenk çalışma ektedir.Yardımlarınızı rica ediyorum şimdiden teşekkürler.

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu denermisiniz.

Option Explicit
 
Sub BUL_İŞARET_EKLE()
    Dim Sayfa As Worksheet, Aranan_Veri As Variant
    Dim Bul As Range, Adres As String
 
    Aranan_Veri = Application.InputBox("Lütfen aramak istediğiniz veriyi giriniz !", "ARANAN VERİ")
 
    If Aranan_Veri = False Then
    MsgBox "Arama işlemi iptal edilmiştir.", vbInformation
    Exit Sub
    End If
 
    If Aranan_Veri = "" Then
    MsgBox "Lütfen aramak istediğiniz veriyi giriniz !", vbExclamation
    Exit Sub
    End If
 
    For Each Sayfa In Worksheets
        Set Bul = Sayfa.Cells.Find(Aranan_Veri, LookAt:=xlWhole)
        If Not Bul Is Nothing Then
        Adres = Bul.Address
        Do
        Sayfa.Range(Adres).Offset(0, 1) = "*"
        Set Bul = Sayfa.Cells.FindNext(Bul)
        Loop While Not Bul Is Nothing And Bul.Address <> Adres
        End If
    Next
 
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[TheDarkness]

Korhan bey öncelikle ilginize cok teşekkür ederim.Verdiğiniz kod gercekden işime yaradı sağolun.Ben barkod okuyucuyla hücrelerdeki verileri bulup işaretlıyordum bu yaklaşık her sayfada 50 şer satırdan oluşan veriler oluyordu.Çalışma kitabında işim bitene kadar bu kodu çalıştırabılırmıyız.Yani işleminiz tamamlanmıstır yazısı çıkmasın ve aradıgım veriyi bulamadıgım zaman arama işlemi iptal edilmiştir demesin her işlemden sonra tekrar tekrar çalıştırmıyayım bu kodu.Çunkı bazen barkod okuyucuyla arattıgım veriyi çalışma kıtabında bulamıyabılıyorum.Bu konuda da yardımcı olabilirseniz çok memnun olurum.Tekrardan çok teşekkür eder paylaşımlarınızın devamını dilerim.

 

[Korhan Ayhan]

Selamlar,

Barkod okuyucu ile veriyi excelde bir hücreye aktarabiliyorsanız kodu sayfanın kod bölümüne yazarak otomatik çalışacak şekilde düzenleyebiliriz.

 

[TheDarkness]

Korhan bey merhaba bir süredir ilgilenemiyorum bu konuyla geç cvp verdiğim için kusura bakmayın bu en son yazdığınız msj istinaden sizden ricam bana bir örnek çalışma hazırlayabilirmisiniz.Tekrardan teşekkür ederim kolay gelsin iyi çalışmalar.

 

[baydeniro]

Paylaşım için teşekkürler

 

[Korhan Ayhan]

Selamlar,

Sn. TheDarkness,

Siz barkod okuyucudan veri okuttuğunuz zaman veriyi excel hücresine atabiliyor musunuz? Eğer bu işlemi yapabiliyorsanız sabit bir sayfaya bu veriyi belli bir hücreye atarak bu hücrenin değişiminde çalışacak şekilde kodu düzenleyebiliriz.

 

[izcik]

Merhaba. Ben kod kullanmayı ne yazık ki hiç bilmiyorum. Fakat excelde veri arayıp yanına işaret koyma gereksinim çok oluyor. Bundan dolayı her seferinde ctrl+f yi kapatıp işareti manuel olarak koyuyorum. Eğer bu kod ile otomatik yapılabiliyorsa kullanmayı çok isterim. nasıl yapılıyor bu kodlar? Not: Excel 2000 Türkçe kullanıyorum

 

[Korhan Ayhan]

Selamlar,

Sn. izcik,

Kod yazmayı öğrenmeniz için forumumuzun dersane bölümünü incelemelisiniz. Eksikleri olsada size büyük ölçüde katkı sağlayacaktır. Kafanızda bazı olgular belirmeye başladığında ise forumda kodlarla yanıtlanmış soruları inceleyerek ve bol bol uygulamalar yaparak kendinizi geliştirebilirsiniz. Gerekiyorsa forumda satışa sunulan kitaplardan edinerek bilgilerinizi pekiştirebilirsiniz. Aşağıdaki linkteki konuları inceleyerek işe başlayabilirsiniz. Kolay gelsin.

Excel Dersanesi

 

[izcik]

Teşekkür ederim. Sitenize yeni üye olduğum için hem hevesli hem de sevinçliyim. Çünkü daha ilk gün bir çok bilmediğim ve faydalı bilgi öğrendim. Eğer kusuruma bakmazsanız bir şey rica etmem gerekiyor; tabii mümkün ise. Yukarıdaki bahsi geçen dosyanın örneğini bildiğimiz excel dosyası olarak kaydedebilir misiniz? Örnek binlerce veri hücresi içeren bir excel sayfam var. ve bu sayfada (örnek) KIRMIZI kelimesi geçen hücreleri Ctrl + F ile buluyorum ve yanına otomatik olarak işaret koymasını istiyorum.
İyi çalışmalar

 

[Korhan Ayhan]

Selamlar,

Sn. izcik,

Ekteki örnek dosyayı incelermisiniz.

 

[TheDarkness]

Selamlar,

Sn. TheDarkness,

Siz barkod okuyucudan veri okuttuğunuz zaman veriyi excel hücresine atabiliyor musunuz? Eğer bu işlemi yapabiliyorsanız sabit bir sayfaya bu veriyi belli bir hücreye atarak bu hücrenin değişiminde çalışacak şekilde kodu düzenleyebiliriz.

Merhaba Korhan Bey
Evet barkod okuyucudan excel hücresine veriyi okutup atabiliyorum.

 

[izcik]

Harika. Uzmanlık denen şey bu olsa gerek.

 

[izcik]

Kusura bakmayın ama insan çok hevesleniyor. Diyelimki kırmızı kelimesi bir hücrenin içerisinde yalnız geçmiyorsa o zaman da işaret koyabilir mi?

Örnek 1875-KIRMIZI-XXL

İçinde kırmızı kelimesi geçen bütün hücrelerin yanına işaret koyabilir miyiz makro ile?

 

[Korhan Ayhan]

Selamlar,

Sn. TheDarkness,

Ekteki örnek dosyayı incelermisiniz. BARKOD isimli sayfanın A1 hücresine okutacağınız barkodlar otomaik olarak diğer sayfalarda aranacaktır.


Uygulanan kod; (BARKOD isimli sayfanın kod bölümüne uygulayınız.)

Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Sayfa As Worksheet, Say As Integer
    Dim Bul As Range, Adres As String
 
    If Intersect(Target, [A1]) Is Nothing Then Exit Sub
 
    If Target = "" Then
    MsgBox "Lütfen aramak istediğiniz veriyi giriniz !", vbExclamation
    Target.Select
    Exit Sub
    End If
 
    For Each Sayfa In Worksheets
        If Sayfa.Name <> "BARKOD" Then
            Set Bul = Sayfa.Cells.Find(Target, LookAt:=xlWhole)
            If Not Bul Is Nothing Then
            Adres = Bul.Address
            Do
            Sayfa.Select
            Sayfa.Range(Bul.Address).Offset(0, 1) = "*"
            Sayfa.Range(Bul.Address).Select
            Say = Say + 1
            Set Bul = Sayfa.Cells.FindNext(Bul)
            Loop While Not Bul Is Nothing And Bul.Address <> Adres
            End If
        End If
    Next
 
    If Say = 0 Then MsgBox Target & " nolu barkod bulunamamıştır !", vbExclamation, "Dikkat !"
End Sub

 

[Korhan Ayhan]

Selamlar,

Sn. izcik,

Kod içinde aşağıdaki satırı bir sonraki ile değiştirirseniz istediğiniz sonuca ulaşabilirsiniz.

Eski hali;

Set Bul = Cells.Find(Aranan_Veri, LookAt:=xlWhole)

Yeni hali;

Set Bul = Cells.Find(Aranan_Veri, LookAt:=xlPart)

 

[izcik]

Değerli Korhan Ayhan oldu İlk defa böyle bir düzeltme yapmış oldum.

 

[TheDarkness]

Merhaba Korhan bey

Emeğinize sağlık cok teşekkür ederim sizden son bir ricam olacaktı yoruyorum sizide hakkınızı helal edin barkodla aradığım veriyi çalışma kitabında bulduğunda o sayfayadaki hücreye gitse ve bulamadığı zaman da bi uyarı alabilirmiyiz acaba bunuda kod olarak ekleme imkanımız varmı ?

 

[Korhan Ayhan]

Selamlar,

Sn. TheDarkness,

#15 nolu mesajımdaki kodu ve dosyayı güncelledim. İncelermisiniz.

 

[TheDarkness]

Selamlar,

Sn. TheDarkness,

#15 nolu mesajımdaki kodu ve dosyayı güncelledim. İncelermisiniz.

Merhaba Korhan bey

Emeğinize sağlık çok teşekkür ederim paylaşımlarınızın ve başarılarınızın devamını temenni ederim:bravo:k::