iki koşullu yenilenen değerleri sayma

[semarion]

Merhaba,

Herkese iyi günler iyi çalışmalar, ekte bulunan örnekte detaylı şekilde anlatmaya çalıştım kabaca burada da söylemek istiyorum.
Birinci koşul tarihe göre ayırım, ikinci koşul ise gruba göre olarak adlandırılan müşterileri isimlerini, yenilenen değerleri kullanmadan saymak istiyorum.
Örnek excel ektedir.
Yardımlarınızı rica ederim.

Not:

=TOPLA(EĞER(SIKLIK(KAÇINCI(D5:D18,D5:D18,0),KAÇINCI(D5:D18,D5:D18,0))>0,1))

Bu şekilde bir formül var fakat 2017, 2018 ve aynı zamanda ikinci koşul olarak "yeni" - "eski" değerlerini ayırabilecek şekilde sayamıyorum. aslında istediğim şey bu şekilde fakat iki tane daha koşul koyarak geliştirmek istiyorum

 

[Ömer]

Merhaba,

eski için: (dizi formülüdür)

=TOPLA(EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;KAÇINCI(D5:D18;D5:D18;0)));SATIR(D5:D18)-SATIR(D5)+1);1))

yeni için H5 yerine I5 yazarsınız.

 

[semarion]

@Ömer Bey,

Verdiğiniz formülü H6 hücresine yazarak deniyorum. 2017 yılına ait eski müşteri sayısı dataya bakıldığında 2 tane (kırmızı font ile yazdıklarım(biri ABB diğeri ATLAS) fakat sonuç olarak H6 hücresine 1 tane getiriyor.)

diğer bir problem ise;
H4 sütununda ki 2017 tarihini 2018 olarak yazdığımda 2018 yılına ait olanları getirmesi gerekirken #DEĞER hatası vermekte

 

[Ömer]

Formülü denedim, 2017 ve 2018 eski için 2 değerini üretiyor.

Formülü dizi formülüne çevirdiniz mi?

 

[semarion]

Yeni bir şey daha öğrendim. dizi formülünü hiç bilmiyordum
çok teşekkürler elinize sağlık

Formülü denedim, 2017 ve 2018 eski için 2 değerini üretiyor.

Formülü dizi formülüne çevirdiniz mi?

 

[semarion]

@Ömer Bey, Çok özür dileyerek sizden ricam bir ekleme daha yapmak istiyorum.

Örnek olarak eklediğim excel 'i güncelledim sadece "F" Sütununa tutar kısmını ekledim.
Verdiğiniz formül çok iyi bir şekilde işliyor buna bir de ek olarak Müşterinin toplam tutarının (satır değil) 5.000 TL üstü veya altı gibi 3. bir koşul daha oluşturabilir miyiz? aynı formülde kullanılacak şekilde ve değiştirilebilir alan olarak olmasını mümkün müdür?

Excel Örnek2.1 olarak güncelledim sarı alan olarak işaretlediklerimi yeni yazdım

 

[Ömer]

Bu şekilde deneyin.(Dizi formülüdür.)
Formülü hücreye yazdıktan sonra entera basmadan ctrl+shift+enter ile girişini tamamlayın. Bu işlemden sonra formülün başına ve sonuna { } ayraçları otomatik eklenmesi gerekir.

=TOPLA(EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;EĞER(F5:F18>=I8;KAÇINCI(D5:D18;D5:D18;0))));SATIR(D5:D18)-SATIR(D5)+1);1))

 

[semarion]

@Ömer Bey, ilginiz için çok teşekkürler.
Fakat sanırsam satır bazlı olarak değerleri alarak hesaplıyor bu şekilde.
Demek istediğim "H4" sütununda istenilen tarih 2017 ise; "abb" müşterisine ait olan 2017 yılındaki toplam tutarlar üzerinden hesaplanması gerekmekte. Yani "I8" (hedef) hücresine tutar 20.000 TL yazılırsa "abb" müşterisinin 2017 yılında ki toplam tutarları 20.000 'i geçemediği için "H6" (sonuç) hücresinde saymaması gerekiyor. Çünkü "abb" 'nin toplam tutarı örnekteki excel 'de 17.028,43 TL

Bu şekilde deneyin.(Dizi formülüdür.)
Formülü hücreye yazdıktan sonra entera basmadan ctrl+shift+enter ile girişini tamamlayın. Bu işlemden sonra formülün başına ve sonuna { } ayraçları otomatik eklenmesi gerekir.

=TOPLA(EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;EĞER(F5:F18>=I8;KAÇINCI(D5:D18;D5:D18;0))));SATIR(D5:D18)-SATIR(D5)+1);1))

 

[Ömer]

Bu şekilde deneyin.

Dizi formülüdür.

=TOPLA(EĞER(ÇOKETOPLA(F5:F18;C5:C18;H4;E5:E18;H5;D5:D18
;EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;KAÇINCI(D5:D18;D5:D18;0)));SATIR(D5:D18)-SATIR(D5)+1)>0;D5:D18))>=I8;1))

 

[semarion]

Dediğinizi denedim çok teşekkürler oldu bu sefer
İyi çalışmalar

 

[semarion]

Bu şekilde deneyin.(Dizi formülüdür.)
Formülü hücreye yazdıktan sonra entera basmadan ctrl+shift+enter ile girişini tamamlayın. Bu işlemden sonra formülün başına ve sonuna { } ayraçları otomatik eklenmesi gerekir.

=TOPLA(EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;EĞER(F5:F18>=I8;KAÇINCI(D5:D18;D5:D18;0))));SATIR(D5:D18)-SATIR(D5)+1);1))

@Ömer Bey Merhaba,

Bahse konu verdiğiniz formülün içerisine bir kıstas daha ekleyebiliyor muyuz?
Örnek2.1 excel 'inde bulunan B5:B18 sütununda isimler olacak şekilde (ahmet,mehmet,ayşe gibi) yazılsa ve "I10" hücresine yazılan isme göre sonucunu alabilmemiz gibi bir şart daha ekleyebilir miyiz ?

=TOPLA(EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;EĞER(F5:F18>=I8;KAÇINCI(D5:D18;D5:D18;0))));SATIR(D5:D18)-SATIR(D5)+1);1))

Kuralın içerisinde ben bir =eğer daha eklemeye çalıştım fakat sonuç alamadım :s
Bu arada formül gayet iyi bir şekilde işliyor tekrardan teşekkürler

 

[Ömer]

Bu şekilde deneyin. Dizi formülüdür.

=TOPLA(EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;EĞER(F5:F18>=I8;EĞER(B5:B18=I10;KAÇINCI(D5:D18;D5:D18;0)))))
;SATIR(D5:D18)-SATIR(D5)+1);1))

.

 

[semarion]

Teşekkürler

 

[semarion]

Bu şekilde deneyin. Dizi formülüdür.

=TOPLA(EĞER(SIKLIK(EĞER(C5:C18=H4;EĞER(E5:E18=H5;EĞER(F5:F18>=I8;EĞER(B5:B18=I10;KAÇINCI(D5:D18;D5:D18;0)))))
;SATIR(D5:D18)-SATIR(D5)+1);1))

.

Merhaba konuyu tekrardan canlandırmak istiyorum izninizle,
Bu formülün içerisine tarih aralıklarında hesaplama yapması için örneğin; sayfa1!$W:$W;">="&$C$1 ve sayfa1!$W:$W;">="&$C$2 gibi ölçeklerinde yazılmasını denedim fakat yapamadım. yardımcı olabilir misiniz

NOT: "W" Sütununu örnek olarak söyledim başka bir sütunda olabilir; data içerisinde "W" sütunu satırlara ait tarihleri içeriyor.
aynı şekilde c1 ve c2 hücrelerini de örnek olarak yazdım.

 

[Ömer]

İstediğiniz bu mu?

Dizi formülüdür.

=TOPLA(EĞER(SIKLIK(EĞER(W5:W18>=C1;EĞER(W5:W18<=C2;EĞER(C5:C18=H4;EĞER(E5:E18=H5;EĞER(F5:F18>=I8;EĞER(B5:B18=I10
;KAÇINCI(D5:D18;D5:D18;0)))))));SATIR(D5:D18)-SATIR(D5)+1);1))

 

[semarion]

Evet doğrudur ömer bey bende bu şekilde deniyorum ama sadece 6 ay içerisindekileri hesaplayabiliyorum. 6 ay ve üzeri bir değer filtresi istediğimde #YOK hatası alıyorum.

 

[Ömer]

Hata aldığınız dosyayla ilgili örnek ekleyebilir misiniz.