Soru Değeri 0 olanları Göster-Gösterme eklentisi

[mehmetd]

Sayın Arkadaşlar günaydın

Tüm excel sayfalarımda kullanabileceğim değeri 0 olan verileri göster veya gösterme eklentisi menüsü nasıl yapabilirim. şu şekilde bir kod buldum ama daha başka bir ol veya eklenti olarak nasıl yapabilirim. yardımlarınız için şimdiden teşekkürler

Sub SifirlariGizle()
ActiveWindow.DisplayZeros = False
End Sub

Sub SifirlariGoster()
ActiveWindow.DisplayZeros = True
End Sub

 

[leguminosea]

Dosya>Seçenekler>Gelişmiş sekmesinde
sağ taraftan
"Bu çalışma Sayfası için görüntüleme seçenekleri" bölümü altında
"Değeri sıfır olan hücrelerde sıfır göster"
satırının tik işaretini kaldırın.

 

[Biolightant]

Merhaba,
bu şekilde bir şey mi istemiştiniz.

Makro kaydet yaparken kısayol tuşu olarak ben büyük S harfini verdim
her hangi bir hücre seçtikten sonra makro kaydını durdurdum.

otomatik oluşturulan makroyu

Sub Makro1()
'
' Makro1 Makro
' Sıfır Göster / Gizle
'
' Klavye Kısayolu: Ctrl+Shift+S
'
    Range("C6").Select
End Sub

şu şekilde değiştirdim

Sub Makro1()
'
' Makro1 Makro
' Sıfır Göster / Gizle
'
' Klavye Kısayolu: Ctrl+Shift+S
'
    ActiveWindow.DisplayZeros = Not ActiveWindow.DisplayZeros
End Sub

artık klavyede Ctrl+Shift+S tuşlarına tıkladığında
SIFIR Gözküyor sa Gizliyor, Gizliyse Gösteriyor.

 

[Biolightant]

@mehmetd Çözüm oldu mu?

 

[mehmetd]

Sn. Biolightant öncelikle ilginiz için teşekkürler. kodlar çalışıyor fakat. menü olarak ekleyemedim. menü olarak hızlı bir şekilde ulaşabileceğim bir hala getirebilseydim iyi olacaktı. Yine de yardım için çok teşekkür ederim.

 

[Korhan Ayhan]

Merhaba,

Oluşturduğunuz VBA makrolarını Ribbon menüsüne ekleyip tüm Excel dosyalarında kullanabilirsiniz. Bunun için en sağlıklı yöntem makroyu Kişisel Makro Çalışma Kitabı (PERSONAL.XLSB) içine koymaktır.
Yöntem 1 — PERSONAL.XLSB ile tüm Excel’lerde kullanma (Önerilen)

1. PERSONAL.XLSB oluşturma
Eğer yoksa:
Excel açın
Görünüm → Makrolar → Makro Kaydet
“Makroyu şuraya kaydet” kısmında:
Kişisel Makro Çalışma Kitabı
Rastgele küçük bir işlem yapın
Kaydı durdurun
Böylece PERSONAL.XLSB oluşur.

2. Makroyu PERSONAL.XLSB içine taşıma
ALT + F11
VBA Project kısmında:
VBAProject(PERSONAL.XLSB)

Module içine kodlarınızı yapıştırın

Örneğin: VB

Sub SifirlariGosterGizle()
ActiveWindow.DisplayZeros = Not ActiveWindow.DisplayZeros
End Sub


3. Ribbon’a ekleme
Dosya → Seçenekler
Şeridi Özelleştir
Sağ tarafta:
Yeni Sekme oluştur veya mevcut sekme seç
Sol tarafta:
“Makrolar” seç
PERSONAL.XLSB içindeki makroyu bulun
Ekle
İsterseniz:
ikon değiştir
isim değiştir

Artık tüm Excel dosyalarında çalışır.

Alternatif Yöntemler

Hızlı Erişim Araç Çubuğu (QAT)
Ribbon yerine üstteki küçük alana ekleyebilirsiniz.

Avantaj:
Her zaman görünür
Daha hızlı erişim
XLAM Add-in yöntemi (Profesyonel çözüm)
Çok sayıda makro varsa en temiz yöntemdir.

Avantajları:
Ribbon özelleştirme
Versiyon kontrolü
Dağıtım kolaylığı
Başka bilgisayarlara kurulum kolay

Adımlar:
Dosyayı:
.xlam olarak kaydet
Excel:
Dosya → Seçenekler → Eklentiler
Excel Eklentileri → Git
Gözat → XLAM seç
Böylece kalıcı olur.

Önemli Notlar
Makro güvenliği
Başka bilgisayarlarda:
Makroları etkinleştirmeniz gerekir
Güven Merkezi:
Dosya → Seçenekler → Güven Merkezi

PERSONAL.XLSB konumu
Genelde:
Plain text
C:\Users\Kullanıcı\AppData\Roaming\Microsoft\Excel\XLSTART
Excel açılırken otomatik yüklenir.

Tavsiyem
Eğer:
5-10 civarı kişisel makro kullanıyorsanız: → PERSONAL.XLSB

 

[Biolightant]

Merhaba,
@Korhan Ayhan dediği gibi en pratik ve hızlı yöntem PERSONAL.XLSB oluşturma yöntemi.

ama alternatif olsun diye *.xlam yötemi ile menü oluşturma Araclar.xlam yaptım inceleyebilirsiniz.

ThisWorkbook (BuÇalışmaKitabı) içine:

Option Explicit

Private Sub Workbook_Open()
    ' EKLENTİLER MENÜ SEKMESİNE BAKINIZ...

    Dim cmbBar As CommandBar
    Dim cmbPopup As CommandBarPopup
    Dim cmbButton As CommandBarButton

    Set cmbBar = Application.CommandBars("Worksheet Menu Bar")

    ' Önceden var olan aynı isimli menüyü kaldır
    On Error Resume Next
    cmbBar.Controls("Araclar").Delete
    On Error GoTo 0

    ' Yeni açılır menü ekle
    Set cmbPopup = cmbBar.Controls.Add(Type:=msoControlPopup, Temporary:=True)

    With cmbPopup
        .Caption = "&Araclar"

        ' 1. Buton - Sıfır Göster/Gizle
        Set cmbButton = .Controls.Add(Type:=msoControlButton)
        With cmbButton
            .Caption = "Sıfır Göster/Gizle"
            .OnAction = "'" & ThisWorkbook.Name & "'!SifirGosterGizle"
            .FaceId = 733
        End With
    
'        ' 2. Buton - Sayfa Koruma Aç/Kapat
'        Set cmbButton = .Controls.Add(Type:=msoControlButton)
'        With cmbButton
'            .Caption = "Sayfa Koruma Aç/Kapat"
'            .OnAction = "'" & ThisWorkbook.Name & "'!SayfaKorumaAcKapat"
'            .FaceId = 225
'        End With
    
    End With

End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)

    On Error Resume Next
    Application.CommandBars("Worksheet Menu Bar").Controls("Araclar").Delete
    On Error GoTo 0

End Sub

Standart Module içine:

Option Explicit

Public Sub SifirGosterGizle()
    If ActiveWindow Is Nothing Then Exit Sub
    ActiveWindow.DisplayZeros = Not ActiveWindow.DisplayZeros
End Sub

'Public Sub SayfaKorumaAcKapat()
'    MsgBox "Sayfa koruma makrosu buraya gelecek."
'End Sub

 

[mehmetd]

İlgilenen ve yardım eden arkadaşlara çok teşekkür ediyorum. Konu çözüme kavuşmuştur. Saygılarımla.İyi akşamlar.