ETARİHLİ Formülü

[umiteks]

Merhaba

ETARİHLİ formülüyle oluşturduğum iki hücreden elde ettiğim:

1 yıl, 2 ay, 12 gün

7 yıl, 4 ay, 13 gün

Sonuçlarının toplamını aynı formatta nasıl alabilirim?
Bu iki hücreyi (C2 ve C3) toplamak istiyorum basitçesi.
Normal topla dediğimde 0 değeri çıkıyor.

Yardımınız için şimdiden teşekkürler

 

[muhasebeciyiz]

Excel 2007 tr ye göre cevaplanmıştır:

Metin olarak oluştuğu için Excel bunu sayı gibi toplayamıyor. En sağlam yol, “yıl / ay / gün” sayılarını ayrı ayrı çekip sonra tekrar aynı biçimde birleştirmek.

C2: 1 yıl, 2 ay, 12 gün
C3: 7 yıl, 4 ay, 13 gün
ise şu yardımcı formülleri kullan:

D2 — Yıl
=DEĞER(SOLDAN(C2;BUL(" yıl";C2)-1))

E2 — Ay
=DEĞER(PARÇAAL(C2;BUL(", ";C2)+2;BUL(" ay";C2)-BUL(", ";C2)-2))

F2 — Gün
=DEĞER(PARÇAAL(C2;BUL("ay, ";C2)+4;BUL(" gün";C2)-BUL("ay, ";C2)-4))

Bunları 3. satıra da aşağı çek.

Sonra toplam sonucu için mesela G2’ye:

=(TOPLA(D2:D3)+TAMSAYI((TOPLA(E2:E3)+TAMSAYI(TOPLA(F2:F3)/30))/12))&" yıl, "&MOD(TOPLA(E2:E3)+TAMSAYI(TOPLA(F2:F3)/30);12)&" ay, "&MOD(TOPLA(F2:F3);30)&" gün"

 

[muhasebeciyiz]

Alternatif olarak ;

1. Adım (Süreleri Gün Sayısına Çevirme):
Diyelim ki C2 hücrenizdeki "1 yıl, 2 ay, 12 gün" ifadesini ve C3'ü toplam gün sayısına çevireceğiz. Excel'de 1 yıl ortalama 365.25 gün, 1 ay ise 30.43 gündür.Boş bir hücreye (Örn: D2) şu formülü yapıştırın (C2'deki metni sayılara döker):

=(SAYIYAÇEVİR(PARÇAAL(C2;1;BUL(" y";C2)-1))*365,25)+(SAYIYAÇEVİR(PARÇAAL(C2;BUL("y, ";C2)+3;BUL(" a";C2)-(BUL("y, ";C2)+3)))*30,43)+SAYIYAÇEVİR(PARÇAAL(C2;BUL("a, ";C2)+3;BUL(" g";C2)-(BUL("a, ";C2)+3)))

Bu formülü aşağıya doğru çekerek D3 hücresi için de uygulayın.

2. Adım (Günleri Toplayıp Formatlama):Şimdi elimizde iki sürenin de net gün karşılığı var. Bu iki günü toplayıp (D2+D3) doğrudan standart tarih fonksiyonlarıyla formatlıyoruz. İstediğiniz sonuç hücesine şu formülü yapıştırın:

=YIL(D2+D3)-1900 & " yıl, " & AY(D2+D3)-1 & " ay, " & GÜN(D2+D3) & " gün"

 

[umiteks]

Özür dilerim Hocam. Excel versiyonumu değiştirmeyi unuttum. 2024 kullanıyorum.
Sizin verdiğiniz "=DEĞER(SOLDAN(C2;BUL(" yıl";C2)-1))" formülünü yazdığımda "Bu işlev için çok az bağımsız değişken girdiniz" diyor.

Tablom bu şekilde:

1. TARİH	2. TARİH	2 TARİH ARASI SÜRE
20.10.2016	13.01.2018	1 yıl, 2 ay, 12 gün
19.02.2019	7 yıl, 4 ay, 13 gün

[td]

14.07.2026​

[/td]​

 

[umiteks]

İkinci mesajınızda yazdığınız ilk formül #DEĞER! hatası verdi

 

[Biolightant]

Merhaba,
Alternatif olsun. BB kodlarıyla tablo yapmak için baya uğraştım

​	A​	B​	C​
1​	1. TARİH​	2. TARİH​	2 TARİH ARASI SÜRE​
2​	20.10.2016​	13.01.2018​	Spoyler: 1 yıl, 2 ay, 24 gün =EĞER(VE(A2<>"";B2<>"");ETARİHLİ(A2;B2;"Y")&" yıl, "&ETARİHLİ(A2;B2;"YM")&" ay, "&ETARİHLİ(A2;B2;"MD")&" gün";"")
3​	19.02.2019​	14.07.2026​	Spoyler: 7 yıl, 4 ay, 25 gün =EĞER(VE(A3<>"";B3<>"");ETARİHLİ(A3;B3;"Y")&" yıl, "&ETARİHLİ(A3;B3;"YM")&" ay, "&ETARİHLİ(A3;B3;"MD")&" gün";"")
4​	​	TOPLAM :​	Spoyler: 8 yıl, 7 ay, 17 gün =ETARİHLİ(TARİH(2000;1;1);TARİH(2000;1;1)+TOPLA.ÇARPIM(B2:B3-A2:A3);"Y")&" yıl, "&ETARİHLİ(TARİH(2000;1;1);TARİH(2000;1;1)+TOPLA.ÇARPIM(B2:B3-A2:A3);"YM")&" ay, "&ETARİHLİ(TARİH(2000;1;1);TARİH(2000;1;1)+TOPLA.ÇARPIM(B2:B3-A2:A3);"MD")&" gün"

 

[umiteks]

İkinize de çok teşekkür derim. @Biolightant formülleriniz bende de çalıştı. Elinize sağlık

Fakat şöyle denediğimde 19 gün fazla çıkıyor:​

20.02.2019

1 yıl, 0 ay, 19 gün

[td width="67pt"]

20.02.2020​

[/td]​

 

[Biolightant]

Benim Test ortamı olan Excel 2016 Türkçe de sonuç 1 yıl, 0 ay, 0 gün

​	A​	B​	C​
1​	1. TARİH​	2. TARİH​	2 TARİH ARASI SÜRE​
2​	20.02.2019​	20.02.2020​	Spoyler: 1 yıl, 0 ay, 0 gün =EĞER(VE(A2<>"";B2<>"");ETARİHLİ(A2;B2;"Y")&" yıl, "&ETARİHLİ(A2;B2;"YM")&" ay, "&ETARİHLİ(A2;B2;"MD")&" gün";"")

 

[umiteks]

Çok teşekkür ederim

 

[muhasebeciyiz]

2024 versiyona göre dosyanız alternatif olarak sunulmuştur