Performans durumunu gösterme

[pavlis]

Merhaba arkadaşlar, çok yoğun çalıştığım ve daha çok power query-pivot-dax ile yoğunlaştığım için ihtiyacım olanı yapmaya kafam çalışmadı.

Elimde şubeler, denetim tarihleri ve skorları olan bir tablo var. Yanlarına gelecek skalalar da mevcut. Bunları yanlarına eklemek kolay fakat ilk denetimden itibaren 2-3 kez denetim görenler var. Bunların gidişatını ekte örnek verdiğim şekilde nasıl yapabilirim bilemedim. Yardımcı olursanız çok sevinirim.

Sarı renkle işaretlediklerim yapmak istediğim.
Benzersiz şube kodları, yanında denetimler iyiye mi gidiyor yoksa kötüye mi onun durumu.

İndir Book xlsx

Dosyayı indir Book xlsx

dosya.co

 

[Korhan Ayhan]

Merhaba,

Boş bir hücreye aşağıdaki formülü uygulayınız..

=LET(Benzersiz;BENZERSİZ(B3:B12);
     DÜŞEYYIĞ({"Şube";"Durum"};YATAYYIĞ(Benzersiz;MAP(Benzersiz;LAMBDA(X;
     LET(
         Data;FİLTRE(C3:D12;B3:B12=X);
         Skor;İNDİS(AL(SIRALA(Data;1;-1);1);1;2);
         EĞER(Skor>=5;"Performansı Yüksek";
         EĞER(Skor=4;"Performansı İyileşen";
         EĞER(Skor=3;"Performansı Orta";"Performansı Düşen")))
        ))))))

 

[Korhan Ayhan]

Bu formülde size şubelerin E sütunundaki son satırlarındaki durumları getirir.

=DÜŞEYYIĞ({"Şube";"Durum"};YATAYYIĞ(BENZERSİZ(B3:B12);ÇAPRAZARA(BENZERSİZ(B3:B12);B3:B12;E3:E12;;;-1)))

 

[pavlis]

Merhaba,

Boş bir hücreye aşağıdaki formülü uygulayınız..

=LET(Benzersiz;BENZERSİZ(B3:B12);
     DÜŞEYYIĞ({"Şube";"Durum"};YATAYYIĞ(Benzersiz;MAP(Benzersiz;LAMBDA(X;
     LET(
         Data;FİLTRE(C3:D12;B3:B12=X);
         Skor;İNDİS(AL(SIRALA(Data;1;-1);1);1;2);
         EĞER(Skor>=5;"Performansı Yüksek";
         EĞER(Skor=4;"Performansı İyileşen";
         EĞER(Skor=3;"Performansı Orta";"Performansı Düşen")))
        ))))))

Merhaba hocam dönüş için teşekkür ederim deniyorum

 

[52779]

Altrnatif olarak,
Farklı bir bakış açısıyla,
Belki de Tüm Şubeler ve Tüm Denetim sonuçları, tek bir tabloda olup, koşullu biçimlendirme ile görsellik verilebilir.

Sayfa1 de K2 hücresindeki Tek formül ile komple dökülmeli sonuçlar.
=LET(p;KIRPARALIĞI(B3:E100);q;SIRALA(FİLTRE(p;İNDİS(p;;1)<>"");2);a;İNDİS(q;;1);b;İNDİS(q;;3);c;SIRALA(BENZERSİZ(a));d;KAÇINCI(a;a; );REDUCE(YATAYYIĞ("Şube";SIRALI(;MAK(SIKLIK(d;d))));SIRALI(SATIRSAY(c));LAMBDA(x;y;EĞERHATA(DÜŞEYYIĞ(x;LET(k;İNDİS(c;y);YATAYYIĞ(k;UNICODEKARAKTERİ(9311+SATIRA(FİLTRE(b;a=k))))));""))))

Dosyayı ekliyorum... İncelersiniz...

Performans - Filemail

Click here to view and download these shared files from Filemail.com

www.filemail.com