Topla.Çarpım formülü ile çoklu şartlara göre veriyi saydırmak

[Deniz_Excel]

Arkadaşlar merhaba,

Ekteki linkte koymuş olduğum excel de görebileceğiniz üzere;
Kapsam Kolonunda "Düzeltme" ve "Yeni Çalışma" Olanların hafta kolonunda belirtilen 1 den 4. haftaya kadar olan sürelerde kaç adet olduğunu bulmak istiyorum. (Sonuç 5 adet olmalı)
Bunu Topla.Çarpım formülü kullanarak aşağıdaki gibi yazmaya çalıştığımda sonuç vermiyor.

TOPLA.ÇARPIM((E2:E30={"Düzeltme";"Yeni Çalışma"})*($B$2:$B$30={"1.hafta";"2.hafta";"3.hafta";"4.hafta"}))

Ancak aşağıdaki gibi yazsaydım sadece "Düzeltme" olanları 4 hafta boyunca kaç tane olduğunu veriyor idi. * işaretinin 2 tarafındaki şartlarda da çoklu olarak çalışmasını nasıl sağlayabiliyoruz?

TOPLA.ÇARPIM((E2:E30="Düzeltme")*($B$2:$B$30={"1.hafta";"2.hafta";"3.hafta";"4.hafta"}))


Exceli bu linkten açabilirsiniz.

Topla_Carpim_Sorusu.xlsx dosyasını indir - download

Topla_Carpim_Sorusu.xlsx dosyasını indir, download. Dosya.tc .Dosya Upload. Dosya Paylaş. Dosya Yükle

s7.dosya.tc

 

[Asri]

Düzeltme ve Yeni Çalışmayı beraber kullanınca olmadı.
Çok inceleyemedim. Ancak ilk etapta basit bir çözüm olması açısından.
Bu şekilde deneyin.

=SUMPRODUCT((E2:E30="Düzeltme")*($B$2:$B$30={"1.hafta"\"2.hafta"\"3.hafta"\"4.hafta"}))+SUMPRODUCT((E2:E30="Yeni Çalışma")*($B$2:$B$30={"1.hafta"\"2.hafta"\"3.hafta"\"4.hafta"}))

 

[Korhan Ayhan]

Deneyiniz.

=TOPLA.ÇARPIM(((E2:E30="Düzeltme")+(E2:E30="Yeni Çalışma"))*($B$2:$B$30={"1.hafta";"2.hafta";"3.hafta";"4.hafta"}))

 

[52779]

Selamlar,
TOPLA.ÇARPIM ile Alternatif formüller

=TOPLA.ÇARPIM(ESAYIYSA(KAÇINCI(E2:E30;{"Düzeltme";"Yeni Çalışma"}; ))*ESAYIYSA(KAÇINCI(B2:B30;{"1.hafta";"2.hafta";"3.hafta";"4.hafta"}; )))

ya da
=TOPLA.ÇARPIM(ESAYIYSA(KAÇINCI(E2:E30;{"Düzeltme";"Yeni Çalışma"}; ))*($B$2:$B$30={"1.hafta";"2.hafta";"3.hafta";"4.hafta"}))

yada
=TOPLA.ÇARPIM(((E2:E30="Düzeltme")+(E2:E30="Yeni Çalışma"))*((B2:B30="1.hafta")+(B2:B30="2.hafta")+(B2:B30="3.hafta")+(B2:B30="4.hafta")))

ya da
=TOPLA.ÇARPIM((E2:E30={"Düzeltme";"Yeni Çalışma"})*((B2:B30="1.hafta")+(B2:B30="2.hafta")+(B2:B30="3.hafta")+(B2:B30="4.hafta")))

ya da CTRL+SHIFT+ENTER ile
=TOPLA.ÇARPIM(DÇARP(--(E2:E30={"Düzeltme";"Yeni Çalışma"});{1\1})*(B2:B30={"1.hafta";"2.hafta";"3.hafta";"4.hafta"}))

Dosyanız ekte.....

Topla_Carpim_Sorusu.xlsx dosyasını indir - download

Topla_Carpim_Sorusu.xlsx dosyasını indir, download. Dosya.tc .Dosya Upload. Dosya Paylaş. Dosya Yükle

s7.dosya.tc

 

[Deniz_Excel]

Selamlar,
TOPLA.ÇARPIM ile Alternatif formüller

=TOPLA.ÇARPIM(ESAYIYSA(KAÇINCI(E2:E30;{"Düzeltme";"Yeni Çalışma"}; ))*ESAYIYSA(KAÇINCI(B2:B30;{"1.hafta";"2.hafta";"3.hafta";"4.hafta"}; )))

ya da
=TOPLA.ÇARPIM(ESAYIYSA(KAÇINCI(E2:E30;{"Düzeltme";"Yeni Çalışma"}; ))*($B$2:$B$30={"1.hafta";"2.hafta";"3.hafta";"4.hafta"}))

yada
=TOPLA.ÇARPIM(((E2:E30="Düzeltme")+(E2:E30="Yeni Çalışma"))*((B2:B30="1.hafta")+(B2:B30="2.hafta")+(B2:B30="3.hafta")+(B2:B30="4.hafta")))

ya da
=TOPLA.ÇARPIM((E2:E30={"Düzeltme";"Yeni Çalışma"})*((B2:B30="1.hafta")+(B2:B30="2.hafta")+(B2:B30="3.hafta")+(B2:B30="4.hafta")))

ya da CTRL+SHIFT+ENTER ile
=TOPLA.ÇARPIM(DÇARP(--(E2:E30={"Düzeltme";"Yeni Çalışma"});{1\1})*(B2:B30={"1.hafta";"2.hafta";"3.hafta";"4.hafta"}))

Dosyanız ekte.....

Topla_Carpim_Sorusu.xlsx dosyasını indir - download

Topla_Carpim_Sorusu.xlsx dosyasını indir, download. Dosya.tc .Dosya Upload. Dosya Paylaş. Dosya Yükle

s7.dosya.tc

Çok teşekkürler.
çok faydalı oldu.

 

[52779]

Çok teşekkürler.
çok faydalı oldu.

Ben teşekkür ediyorum...
İyi çalışmalar sizlere..