Çözüldü Yeni formüllere göre çözüm ricam

[assenucler]

Değerli Dostlar,


Dosya 15 yıl önce kullanılan formüllere göre düzenlenmiştir.

Microsoft 365 ev sürümü kullanıyorum.

Bugün itibariyle kullanılmakta olan formüllere göre dosyanın güncellemenizi rica ediyorum.

Saygılar,

 

[muhasebeciyiz]

sayın assenucler bende 365 yok bu şekilde formüller hata veriyor 365 versiyonda denermisiniz

Sonuç olarak, dosyanızı amaçlanan mantığa göre ve güncel Microsoft 365 formüllerini kullanarak güncellemek için:

D21 hücresine girin: = -XLOOKUP(D$20, $B$2:$B$16, XLOOKUP($C21, $B$2:$M$2, $B$2:$M$16)) ($M$2 ve $M$16 aralıklarınızı farklıysa buna göre ayarlayın).
E21 hücresine girin: = -XLOOKUP(E$20, $B$2:$B$16, XLOOKUP($C21, $B$2:$M$2, $B$2:$M$16)) ($M$2 ve $M$16 aralıklarınızı farklıysa buna göre ayarlayın).
F21 hücresine girin: = -XLOOKUP(F$20, $B$2:$B$16, XLOOKUP($C21, $B$2:$M$2, $B$2:$M$16)) ($M$2 ve $M$16 aralıklarınızı farklıysa buna göre ayarlayın).
P21 hücresi: =SUM(D21:O21) (değişiklik yapmanıza gerek yok).
D24 hücresine girin: =SUM(INDIRECT(SUBSTITUTE(ADDRESS(ROW(),COLUMN(),4),ROW(),"") &"$21:" & SUBSTITUTE(ADDRESS(ROW(),COLUMN(),4),ROW(),"") & ROW()-1))

Aralıkları Ayarlayın: $B$2:$B$16, $B$2:$M$2 ve $B$2:$M$16 aralıklarını dikkatlice kontrol edin. Bunlar, arama değerlerinizin ve almak istediğiniz verilerin bulunduğu yerleri doğru bir şekilde yansıtmalıdır.

 

[Ali]

D21 hücresine

=MUTLAK(FİLTRE(FİLTRE($2:$16;$B$2:$B$16=D$20);$2:$2=$C21))

yazıp sağa ve aşağı çekerek tabloyu doldurunuz.

 

[assenucler]

Sayın Muhasebeciyiz,
Sayın Ali,


İlginiz ve çözüme ilişkin yanıtlarınız için yürekten teşekkürler. Allah'ım sizlerden razı olsun.

Her şey gönlünüzce ve rızkınız bol olsun.

Sevgi ve saygılarımla,
Selim

Yaş 79 ve bir göz görmüyor! Rabbime şükürler olsun!

 

[assenucler]

sayın assenucler bende 365 yok bu şekilde formüller hata veriyor 365 versiyonda denermisiniz

Sonuç olarak, dosyanızı amaçlanan mantığa göre ve güncel Microsoft 365 formüllerini kullanarak güncellemek için:

D21 hücresine girin: = -XLOOKUP(D$20, $B$2:$B$16, XLOOKUP($C21, $B$2:$M$2, $B$2:$M$16)) ($M$2 ve $M$16 aralıklarınızı farklıysa buna göre ayarlayın).
E21 hücresine girin: = -XLOOKUP(E$20, $B$2:$B$16, XLOOKUP($C21, $B$2:$M$2, $B$2:$M$16)) ($M$2 ve $M$16 aralıklarınızı farklıysa buna göre ayarlayın).
F21 hücresine girin: = -XLOOKUP(F$20, $B$2:$B$16, XLOOKUP($C21, $B$2:$M$2, $B$2:$M$16)) ($M$2 ve $M$16 aralıklarınızı farklıysa buna göre ayarlayın).
P21 hücresi: =SUM(D21:O21) (değişiklik yapmanıza gerek yok).
D24 hücresine girin: =SUM(INDIRECT(SUBSTITUTE(ADDRESS(ROW(),COLUMN(),4),ROW(),"") &"$21:" & SUBSTITUTE(ADDRESS(ROW(),COLUMN(),4),ROW(),"") & ROW()-1))

Aralıkları Ayarlayın: $B$2:$B$16, $B$2:$M$2 ve $B$2:$M$16 aralıklarını dikkatlice kontrol edin. Bunlar, arama değerlerinizin ve almak istediğiniz verilerin bulunduğu yerleri doğru bir şekilde yansıtmalıdır.

Uygun zamanım olduğunda geri dönüş yapacağım.

 

[Korhan Ayhan]

Bu da tek hücreye uygulanarak tüm listenin (başlıklar ve toplamlar dahil) dökülmeli çözüm için alternatif olsun..

Fonksiyonun çalışması için C20:P24 aralığını temizleyiniz.

Sonrasında C20 hücresine uygulayınız. Tüm liste dökülmeli olarak oluşacaktır.

=LET(
     Aylar; {"OCAK";"ŞUBAT";"MART";"NİSAN";"MAYIS";"HAZİRAN";"TEMMUZ";"AĞUSTOS";"EYLÜL";"EKİM";"KASIM";"ARALIK"};
     Personel; BIRAK(SÜTUNA(C2:P2;1);0);
     Tablo; DEVRİK_DÖNÜŞÜM(B2:P16);
     Satırlar; ÇAPRAZEŞLEŞTİR(Personel; İNDİS(Tablo;;1));
     Sütunlar; ÇAPRAZEŞLEŞTİR(Aylar; İNDİS(Tablo;1;));
     Ham_Veriler; İNDİS(Tablo; Satırlar; Sütunlar);
     Veriler; EĞERYOKSA(Ham_Veriler / -1; 0);

     Satır_Toplamları; BYROW(Veriler; LAMBDA(X; TOPLA(X)));
     Sütun_Toplamları; BYCOL(Veriler; LAMBDA(Y; TOPLA(Y)));
     Genel_Toplam; TOPLA(Veriler);

     Başlık; YATAYYIĞ("SAĞLIK GİDERLERİ"; Aylar; "TOPLAM");
     Satır_Listesi; YATAYYIĞ(Personel; Veriler; Satır_Toplamları);
     Toplam_Satırı; YATAYYIĞ("GENEL TOPLAM"; Sütun_Toplamları; Genel_Toplam);

     DÜŞEYYIĞ(Başlık; Satır_Listesi; Toplam_Satırı)
    )

 

[assenucler]

Sayın Korhan Ayhan,

Değerli üstadım, yazdığınız fonksiyon harika; emek ve paylaşımınız için en içten teşekkürlerimi, sevgi ve saygılarımı sunuyorum.

Selim